python-rx/trunk/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Ilya Elenskiy <elenskiy.ilya@gmail.com>
   3 # Contributor: Julien Nicoulaud <julien.nicoulaud@gmail.com>
   4
   5 pkgname=python-rx
   6 pkgver=3.2.0
   7 pkgrel=4
   8 pkgdesc='Reactive Extensions for Python'
   9 arch=(any)
  10 url=http://reactivex.io
  11 license=(APACHE)
  12 depends=(python)
  13 makedepends=(
  14   git
  15   python-setuptools
  16 )
  17 checkdepends=(
  18   python-coverage
  19   python-nose
  20   python-pytest
  21   python-pytest-asyncio
  22 )
  23 _tag=5054de8874f275ed0de55007b87cff4817b1d9f7
  24 source=(
  25   git+https://github.com/ReactiveX/RxPY.git#tag=${_tag}
  26   python-rx-py311.patch
  27 )
  28 b2sums=('SKIP'
  29         '3062891dcdfec9ad21ec6815aa1f83ad6b898de32339c02cef9369a975719a1d58ab7bb07cc352829264b20bfd9a710905c96cc3b88c31b157ba1336dc77271d')
  30
  31 pkgver() {
  32   cd RxPY
  33   git describe --tags | sed 's/^v//'
  34 }
  35
  36 prepare() {
  37   cd RxPY
  38   # Remove deprecated loop parameter (#575)
  39   # https://github.com/ReactiveX/RxPY/pull/575
  40   git format-patch -1 --stdout 246eabfefd17 | patch -Np1
  41   patch -Np1 -i ../python-rx-py311.patch
  42 }
  43
  44 build() {
  45   cd RxPY
  46   python setup.py build
  47 }
  48
  49 check() {
  50   cd RxPY
  51   python -m pytest
  52 }
  53
  54 package() {
  55   cd RxPY
  56   python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
  57 }
  58
  59 # vim: ts=2 sw=2 et: