rapydscript-ng/trunk/PKGBUILD

   1 # Maintainer: Eli Schwartz <eschwartz@archlinux.org>
   2
   3 pkgname=rapydscript-ng
   4 pkgver=0.7.22
   5 pkgrel=1
   6 pkgdesc="Pythonic JavaScript that doesn't suck"
   7 arch=('any')
   8 url="https://github.com/kovidgoyal/${pkgname}"
   9 license=('BSD')
  10 depends=('nodejs')
  11 makedepends=('git' 'npm')
  12 source=("git+${url}.git?signed#tag=v${pkgver}")
  13 sha256sums=('SKIP')
  14 validpgpkeys=('3CE1780F78DD88DF45194FD706BC317B515ACE7C') # Kovid Goyal (New longer key) <kovid@kovidgoyal.net>
  15
  16 build() {
  17     cd ${pkgname}
  18
  19     npm install --no-optional
  20     bin/rapydscript self --complete
  21     rm -rf release/ && mv dev/ release/
  22 }
  23
  24 check() {
  25     cd ${pkgname}
  26
  27     bin/rapydscript test
  28 }
  29
  30 package() {
  31     cd ${pkgname}
  32
  33     mkdir -p "${pkgdir}"/usr/{bin,lib/node_modules/rapydscript-ng/}
  34     cp -r * "${pkgdir}"/usr/lib/node_modules/rapydscript-ng/
  35     # Non-deterministic race in npm gives 777 permissions to random directories.
  36     # See https://github.com/npm/npm/issues/9359 for details.
  37     find "${pkgdir}"/usr -type d -exec chmod 755 {} +
  38
  39     ln -s ../lib/node_modules/rapydscript-ng/bin/rapydscript "${pkgdir}"/usr/bin/rapydscript
  40
  41     install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  42 }