ruby-async-websocket/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2
   3 pkgname=ruby-async-websocket
   4 pkgver=0.25.0
   5 _commit=f05d33646a4b7866581c43c683ff0abbadf8acc2
   6 pkgrel=1
   7 pkgdesc='An async websocket library on top of websocket-driver'
   8 arch=(any)
   9 url='https://github.com/socketry/async-websocket'
  10 license=(MIT)
  11 depends=(ruby-async-http ruby-async-io ruby-protocol-rack ruby-protocol-websocket)
  12 makedepends=(git)
  13 checkdepends=(ruby-bake-modernize ruby-bake-test ruby-bake-test-external ruby-rack ruby-covered
  14               ruby-sus ruby-sus-fixtures-async-http)
  15 options=(!emptydirs)
  16 source=(git+https://github.com/socketry/async-websocket.git#commit=$_commit)
  17 sha256sums=('SKIP')
  18
  19 prepare() {
  20   cd async-websocket
  21   sed -r -e 's|~>|>=|g' -e '/signing_key/d' -i async-websocket.gemspec
  22   sed -i '/bake-gem/d;/utopia-project/d' gems.rb
  23 }
  24
  25 build() {
  26   local _gemdir="$(gem env gemdir)"
  27   cd async-websocket
  28   gem build async-websocket.gemspec
  29   gem install \
  30     --local \
  31     --verbose \
  32     --ignore-dependencies \
  33     --no-user-install \
  34     --install-dir "tmp_install/$_gemdir" \
  35     --bindir "tmp_install/usr/bin" \
  36     async-websocket-$pkgver.gem
  37   find "tmp_install/$_gemdir/gems/" \
  38     -type f \
  39     \( \
  40         -iname "*.o" -o \
  41         -iname "*.c" -o \
  42         -iname "*.so" -o \
  43         -iname "*.time" -o \
  44         -iname "gem.build_complete" -o \
  45         -iname "Makefile" \
  46     \) \
  47     -delete
  48   rm -r tmp_install/$_gemdir/cache
  49 }
  50
  51 check() {
  52   local _gemdir="$(gem env gemdir)"
  53   cd async-websocket
  54   GEM_HOME="tmp_install/$_gemdir" bake test
  55 }
  56
  57 package() {
  58   cd async-websocket
  59   cp -a tmp_install/* "$pkgdir"/
  60   install -Dm644 license.md -t "$pkgdir"/usr/share/licenses/$pkgname/
  61 }