ruby-manpages/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 _gemname=manpages
   4 pkgname=ruby-manpages
   5 pkgver=0.6.1
   6 pkgrel=4
   7 pkgdesc='Man pages support for ruby gems'
   8 url='https://github.com/bitboxer/manpages'
   9 arch=('any')
  10 license=('MIT')
  11 depends=('ruby' 'ruby-rdoc')
  12 options=('!emptydirs')
  13 source=(${pkgname}-${pkgver}.tar.gz::https://github.com/bitboxer/manpages/archive/${pkgver}.tar.gz)
  14 sha256sums=('c25fa337fd162c6442a42073d4aaf9468c2df49d7bfb953bd887790ca3872ced')
  15 sha512sums=('e2194cd8a8f91265203cfb2f63948c9f7a5c5c60c9435acebefbea7b88fcdd3da5dc08acf5589c42c06a8688e304ab88296216de23ac0d729ec893a6cc308a61')
  16
  17 prepare() {
  18   cd ${_gemname}-${pkgver}
  19   sed -r 's|~>|>=|g' -i ${_gemname}.gemspec # don't give a fuck about rubys bla bla
  20   sed 's|git ls-files -z|find -type f -print0\|sed "s,\\\\./,,g"|' -i ${_gemname}.gemspec
  21 }
  22
  23 build() {
  24   cd ${_gemname}-${pkgver}
  25   gem build ${_gemname}.gemspec
  26 }
  27
  28
  29 package() {
  30   cd ${_gemname}-${pkgver}
  31   local _gemdir="$(gem env gemdir)"
  32   gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
  33   install -Dm 644 README.md CHANGELOG.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  34   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  35   rm "${pkgdir}/${_gemdir}/cache/${_gemname}-${pkgver}.gem"
  36 }
  37
  38 # vim: ts=2 sw=2 et: