sn0int/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Santiago Torres-Arias <santiago[at]archlinux[dot]org>
   3 # Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
   4
   5 pkgname=sn0int
   6 pkgver=0.25.0
   7 pkgrel=1
   8 pkgdesc='Semi-automatic OSINT framework and package manager'
   9 url='https://github.com/kpcyrd/sn0int'
  10 arch=('x86_64')
  11 license=('GPL3')
  12 depends=('libcap' 'lua52' 'sqlite' 'libseccomp.so' 'libsodium' 'geoip2-database' 'publicsuffix-list')
  13 makedepends=('cargo' 'python-sphinx')
  14 install=sn0int.install
  15 options=(!lto)
  16 source=(https://github.com/kpcyrd/${pkgname}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz
  17         https://github.com/kpcyrd/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz.asc)
  18 sha512sums=('a95ac5a8ba1004db9153d534328c676dc848fee40901b7924aa437cfc0b511e382a9e30d9c48cf2c2e129d0485a74120e35d52464be33a84f761561cd8055bb7'
  19             'SKIP')
  20 b2sums=('1844ad67095a5766d3cc7df37272975aba78aa581e29c559892adfe293f8d0a63363952215c4de5fd40a2b7bb39f35e9ec089338f7fad7cd36afd82bc8dc97d5'
  21         'SKIP')
  22
  23 validpgpkeys=("64B13F7117D6E07D661BBCE0FE763A64F5E54FD6")
  24
  25
  26 prepare() {
  27   cd "${pkgname}-${pkgver}"
  28   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  29 }
  30
  31 build() {
  32   cd ${pkgname}-${pkgver}
  33   cargo build --frozen --release
  34   make -C docs man
  35 }
  36
  37 check() {
  38   cd ${pkgname}-${pkgver}
  39   cargo test --frozen
  40 }
  41
  42 package() {
  43   cd ${pkgname}-${pkgver}
  44   install -Dm 755 target/release/${pkgname} "${pkgdir}/usr/bin/${pkgname}"
  45
  46   install -d "${pkgdir}/usr/share/bash-completion/completions" \
  47              "${pkgdir}/usr/share/zsh/site-functions" \
  48              "${pkgdir}/usr/share/fish/vendor_completions.d"
  49   "${pkgdir}/usr/bin/sn0int" completions bash > "${pkgdir}/usr/share/bash-completion/completions/sn0int"
  50   "${pkgdir}/usr/bin/sn0int" completions zsh > "${pkgdir}/usr/share/zsh/site-functions/_sn0int"
  51   "${pkgdir}/usr/bin/sn0int" completions fish > "${pkgdir}/usr/share/fish/vendor_completions.d/sn0int.fish"
  52
  53   install -Dm 644 docs/_build/man/sn0int.1 -t "${pkgdir}/usr/share/man/man1"
  54   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  55   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  56 }
  57
  58 # vim: ts=2 sw=2 et: