steam/repos/multilib-x86_64/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Giancarlo Razzolini <grazzolini@archlinux.org>
   3 # Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
   4 # Contributor: K900 <k0009000@gmail.com>
   5
   6 pkgname=steam
   7 pkgver=1.0.0.76
   8 pkgrel=1
   9 pkgdesc="Valve's digital software delivery system"
  10 url='https://steampowered.com/'
  11 arch=('x86_64')
  12 license=('custom')
  13 depends=('bash' 'desktop-file-utils' 'diffutils' 'hicolor-icon-theme' 'curl' 'dbus'
  14          'freetype2' 'gdk-pixbuf2' 'ttf-font' 'zenity' 'lsb-release' 'nss' 'usbutils'
  15          'xorg-xrandr' 'vulkan-driver' 'vulkan-icd-loader' 'lsof' 'python')
  16 depends_x86_64=('lib32-libgl' 'lib32-gcc-libs' 'lib32-libx11' 'lib32-libxss'
  17                 'lib32-alsa-plugins' 'lib32-libgpg-error'
  18                 'lib32-nss' 'lib32-vulkan-driver' 'lib32-vulkan-icd-loader')
  19 optdepends=('steam-native-runtime: steam native runtime support')
  20 source=(https://repo.steampowered.com/${pkgname}/pool/${pkgname}/s/${pkgname}/${pkgname}_${pkgver}{.tar.gz,.dsc}
  21         steam-runtime.sh)
  22 sha512sums=('cb2fd0a55f23c92ec46c27edd4595421d4ac346f8cd4faeb2b8e0b017232ac637ee20ed3a00c8b79ee106e922ade6efc5e09c970807757cc372fa9fc26fe9ed1'
  23             '1f179c8a9eab81b5fa9cc1274398322ae5f9dcf5f0d900a43a0a2ac53549389dd3508757d4624291e99c09fc37bf98e2a0247b3e1299d668dc6dc9986372f0ca'
  24             '5e75c019e9fe8c67d686c4e3343dac1180a69a4bdb7d39b333415c63201eef9b98da5619dbf6fd8daa6884e65bc7f8afc9e52778682425e5a75987d527eae6f0')
  25 b2sums=('de38c2604b3fb7a65a25d317718272c607f60e4bedf2efb83eebcf30e01fbccd94fac572f65e6b995e95e981191c241138cd9a9a6f51ba768cd0b3efd9edc0a5'
  26         '6d034e6c5d90d62b2d96f1e0760fff57a1196e7a7bfd7da26989cfc567a40bb90568c2885f1e1fdd7f83dc68bcd9d8166a684abc315967bff85607b5b7bc1e52'
  27         'c6bac99336b7c30fec7cdbaf9e949555c687dd9dff50bcae136134d6314f4b841f5fc66ddb2caac1b003690b926fd4afbdc11da143b4674db4b75f27709fdd23')
  28 validpgpkeys=('BA1816EF8E75005FCF5E27A1F24AEA9FB05498B7') # linux@steampowered.com
  29
  30 prepare() {
  31   cd ${pkgname}-launcher
  32   # apply roundups for udev rules
  33   sed -r 's|("0666")|"0660", TAG+="uaccess"|g' -i subprojects/steam-devices/60-steam-input.rules
  34   sed -r 's|("misc")|\1, OPTIONS+="static_node=uinput"|g' -i subprojects/steam-devices/60-steam-input.rules
  35   sed -r 's|(, TAG\+="uaccess")|, MODE="0660"\1|g' -i subprojects/steam-devices/60-steam-vr.rules
  36
  37   # separated runtime/native desktop files
  38   sed -r 's|(Name=Steam)|\1 (Runtime)|' -i steam.desktop
  39   sed -r 's|(/usr/bin/steam)|\1-runtime|' -i steam.desktop
  40 }
  41
  42 package() {
  43   cd ${pkgname}-launcher
  44   make DESTDIR="${pkgdir}" install
  45
  46   install -Dm 755 "${srcdir}/steam-runtime.sh" "${pkgdir}/usr/bin/steam-runtime"
  47   install -d "${pkgdir}/usr/lib/steam"
  48   mv "${pkgdir}/usr/bin/steam" "${pkgdir}/usr/lib/steam/steam"
  49   ln -sf /usr/bin/steam-runtime "${pkgdir}/usr/bin/steam"
  50
  51   install -Dm 644 COPYING steam_subscriber_agreement.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
  52   install -Dm 644 debian/changelog -t "${pkgdir}/usr/share/doc/${pkgname}"
  53
  54   # blank steamdeps because apt-get
  55   ln -sf /usr/bin/true "${pkgdir}/usr/bin/steamdeps"
  56
  57   install -Dm 644 subprojects/steam-devices/60-steam-input.rules \
  58     "${pkgdir}/usr/lib/udev/rules.d/70-steam-input.rules"
  59   install -Dm 644 subprojects/steam-devices/60-steam-vr.rules \
  60     "${pkgdir}/usr/lib/udev/rules.d/70-steam-vr.rules"
  61 }
  62
  63 # vim: ts=2 sw=2 et: