tpm2-tss-engine/trunk/PKGBUILD

   1 # Maintainer: Jonas Witschel <diabonas@archlinux.org>
   2 pkgname=tpm2-tss-engine
   3 pkgver=1.1.0
   4 pkgrel=2
   5 pkgdesc='OpenSSL engine for Trusted Platform Module 2.0 devices'
   6 arch=('x86_64')
   7 url='https://github.com/tpm2-software/tpm2-tss-engine'
   8 license=('BSD')
   9 depends=('openssl' 'tpm2-tss' 'libtss2-esys.so' 'libtss2-mu.so' 'libtss2-tctildr.so')
  10 checkdepends=('cmocka' 'expect' 'ibm-sw-tpm2' 'iproute2' 'tpm2-tools')
  11 source=("$url/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz"{,.asc})
  12 sha512sums=('5d2e08178be54350e8672245023d601a0d9d520f8c49e977af49d7c59b91d033c14b4a347b71e042fe7c5ff12af9fcc43b69fd1dc83a9f0db12d47d43e1107f4'
  13             'SKIP')
  14 validpgpkeys=('D6B4D8BAC7E0CC97DCD4AC7272E88B53F7A95D84') # Andreas Fuchs <andreas.fuchs@sit.fraunhofer.de>
  15
  16 prepare() {
  17         cd "$pkgname-$pkgver"
  18         sed -i 's/-Werror//' configure
  19         sed -i 's/unable to load Private Key/\0\\|failed loading private key/' test/failload.sh
  20 }
  21
  22 build() {
  23         cd "$pkgname-$pkgver"
  24         ./configure --prefix=/usr $( ((CHECKFUNC)) && echo --enable-unit --enable-integration)
  25         make
  26 }
  27
  28 check() {
  29         cd "$pkgname-$pkgver"
  30         make check
  31 }
  32
  33 package() {
  34         cd "$pkgname-$pkgver"
  35         make DESTDIR="$pkgdir" install
  36         install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  37 }