tup/trunk/PKGBUILD

   1 # Maintainer: Anatol Pomozov <anatol.pomozov@gmail.com>
   2 # Contributor: Arvid Norlander <anmaster A_T tele2 d_o_t (ccTLD for Sweden, which is se)>
   3 # Contributor: Patrick McCarty <pnorcks at gmail dot com>
   4
   5 pkgname=tup
   6 pkgver=0.7.11
   7 pkgrel=1
   8 pkgdesc='A fast, file-based build system'
   9 arch=(x86_64)
  10 url='http://gittup.org/tup/index.html'
  11 license=(GPL2)
  12 depends=(fuse3 pcre)
  13 install=tup.install
  14 source=($pkgname-$pkgver.tar.gz::https://github.com/gittup/tup/archive/v$pkgver.tar.gz)
  15 sha256sums=('be24dff5f1f32cc85c73398487a756b4a393adab5e4d8500fd5164909d3e85b9')
  16
  17 prepare() {
  18   cd tup-$pkgver
  19
  20   sed "s/\`git describe\`/$pkgver/" -i src/tup/link.sh
  21   echo "CFLAGS += $CFLAGS" >> Tuprules.tup
  22   echo "LDFLAGS += $LDFLAGS" >> Tuprules.tup
  23 }
  24
  25 build() {
  26   cd tup-$pkgver
  27
  28   # Clean environment does not allow to use fuse so ./bootstrap does not work
  29   ./build.sh
  30   ./build/tup init
  31   ./build/tup generate runme.sh
  32   ./runme.sh
  33 }
  34
  35 package() {
  36   cd tup-$pkgver
  37
  38   install -d "$pkgdir"/usr/bin "$pkgdir"/usr/share/man/man1 "$pkgdir"/usr/share/vim/vimfiles/{syntax,ftdetect}
  39   install -m755 -t "$pkgdir"/usr/bin tup
  40   install -m644 -t "$pkgdir"/usr/share/man/man1 tup.1
  41   install -m644 -t "$pkgdir"/usr/share/vim/vimfiles/syntax contrib/syntax/tup.vim
  42   echo 'au BufNewFile,BufRead Tupfile,*.tup setf tup' > "$pkgdir"/usr/share/vim/vimfiles/ftdetect/tup.vim
  43 }