xf86-video-qxl/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Giancarlo Razzolini <grazzolini@archlinux.org>
   2 # Contributor: Christian Hesse <mail@eworm.de>
   3 # Contributor: Yonathan Dossow
   4 # Contributor: Ansgar Taflinski <ataflinski@uni-koblenz.de>
   5
   6 pkgname=xf86-video-qxl
   7 pkgver=0.1.6
   8 pkgrel=1
   9 pkgdesc='Xorg X11 qxl video driver'
  10 arch=('x86_64')
  11 url='https://www.x.org'
  12 license=('MIT')
  13 groups=('xorg-drivers')
  14 depends=('spice' 'systemd-libs' 'libxfont2')
  15 optdepends=('python: for Xspice')
  16 makedepends=('xorg-server-devel' 'X-ABI-VIDEODRV_VERSION=25.2' 'spice-protocol'
  17     'xorgproto' 'git' 'libcacard')
  18 conflicts=('xf86-video-qxl-git' 'X-ABI-VIDEODRV_VERSION<25' 'X-ABI-VIDEODRV_VERSION>=26')
  19 validpgpkeys=('94A9F75661F77A6168649B23A9D8C21429AC6C82')
  20 source=("https://xorg.freedesktop.org/releases/individual/driver/${pkgname}-${pkgver}.tar.xz"{,.sig})
  21 sha256sums=('2ad39558db47a8fcc036e290e0b084671e58d43344a57b279abd870c4c67965f'
  22             'SKIP')
  23 validpgpkeys=('3C2C43D9447D5938EF4551EBE23B7E70B467F0BF') # Peter Hutterer (Who-T) <office@who-t.net>
  24
  25 build() {
  26     cd ${pkgname}-${pkgver}
  27
  28     # Since pacman 5.0.2-2, hardened flags are now enabled in makepkg.conf
  29     # With them, module fail to load with undefined symbol.
  30     # See https://bugs.archlinux.org/task/55102 / https://bugs.archlinux.org/task/54845
  31     export CFLAGS=${CFLAGS/-fno-plt}
  32     export CXXFLAGS=${CXXFLAGS/-fno-plt}
  33     export LDFLAGS=${LDFLAGS/,-z,now}
  34
  35     autoreconf -fi
  36     ./configure --enable-xspice --prefix=/usr
  37     make
  38 }
  39
  40 package() {
  41     cd ${pkgname}-${pkgver}
  42
  43     make DESTDIR="${pkgdir}/" install
  44
  45     install -v -Dm0755 scripts/Xspice "${pkgdir}"/usr/bin/Xspice
  46     install -Dm644 "${srcdir}"/${pkgname}-${pkgver}/COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
  47 }