yass/trunk/PKGBUILD

   1 # Maintainer: David Runge <dave@sleepmap.de>
   2 pkgname=yass
   3 pkgver=0.1.0
   4 pkgrel=2
   5 pkgdesc="Yet Another Scrolling Scope"
   6 arch=('x86_64')
   7 url="https://kokkinizita.linuxaudio.org/linuxaudio/"
   8 license=('GPL2')
   9 groups=('pro-audio')
  10 depends=('clthreads' 'clxclient' 'jack')
  11 makedepends=('gendesk')
  12 backup=('etc/yass.conf')
  13 source=("https://kokkinizita.linuxaudio.org/linuxaudio/downloads/$pkgname-$pkgver.tar.bz2")
  14 sha512sums=('c8107368ea014c0f078cd73df325aa68e15af2ce8797e02dbcc4cff4b03b753f9dd7301d9ef675960021a94ca47354cc93cae3f0e8abbbece54d9333ee4f77a2')
  15 validpgpkeys=()
  16
  17 prepare() {
  18   cd "$pkgname-$pkgver"
  19   sed -e '/native/d' \
  20       -i source/Makefile
  21   # XDG desktop files
  22   gendesk -n \
  23           --pkgname ${pkgname} \
  24           --pkgdesc "${pkgdesc}" \
  25           --name YASS \
  26           --categories "AudioVideo;Audio"
  27 }
  28
  29 build() {
  30   cd "$pkgname-$pkgver/source"
  31   make
  32 }
  33
  34 package() {
  35   cd "$pkgname-$pkgver/source"
  36   make DESTDIR="${pkgdir}" PREFIX="/usr" install
  37   # XDG desktop integration
  38   install -vDm 644 "../${pkgname}.desktop" \
  39     -t "${pkgdir}/usr/share/applications/"
  40   # docs
  41   install -vDm 644 ../{AUTHORS,README} -t "${pkgdir}/usr/share/doc/${pkgname}/"
  42   # configuration
  43   install -vDm 644 ../.yassrc "${pkgdir}/etc/yass.conf"
  44 }