libedit/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   3 # Contributor: Vesa Kaihlavirta <vesa@archlinux.org>
   4 # Contributor: Roman Cheplyaka <roma@ro-che.info>
   5
   6 pkgname=libedit
   7 _pkgver=20221030-3.1
   8 pkgver=${_pkgver/-/_}
   9 pkgrel=1
  10 pkgdesc='Command line editor library providing generic line editing, history, and tokenization functions'
  11 url='https://thrysoee.dk/editline/'
  12 arch=('x86_64')
  13 license=('BSD')
  14 depends=('glibc' 'ncurses' 'libncursesw.so')
  15 provides=('libedit.so')
  16 source=(${url}/${pkgname}-${_pkgver}.tar.gz)
  17 sha256sums=('f0925a5adf4b1bf116ee19766b7daa766917aec198747943b1c4edf67a4be2bb')
  18 b2sums=('f4a9784cfc2a30af2778f0e05b6e45ca489555c3009ba050ea19134670ad71fdd099425dee0526dcbb6a1a84f51bd8014ce2540be0535465cb59ab998753833c')
  19
  20 build() {
  21   cd ${pkgname}-${_pkgver}
  22   ./configure --prefix=/usr
  23   make V=1
  24 }
  25
  26 package() {
  27   cd ${pkgname}-${_pkgver}
  28   make DESTDIR="${pkgdir}" install
  29
  30   rm "${pkgdir}"/usr/share/man/man3/history.3 # conflicts with readline
  31   install -Dm 644 "${pkgdir}"/usr/share/man/man3/editline.3 "${pkgdir}"/usr/share/man/man3/el.3
  32
  33   install -Dm 644 ChangeLog -t "${pkgdir}/usr/share/doc/${pkgname}"
  34   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  35 }
  36
  37 # vim:set sw=2 sts=-1 et: