perl-net-ssleay/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   3 # Contributor: Manolis Tzanidakis
   4
   5 pkgname=perl-net-ssleay
   6 _cpanname=Net-SSLeay
   7 pkgver=1.92
   8 pkgrel=2
   9 pkgdesc='Perl bindings for OpenSSL and LibreSSL'
  10 url='https://search.cpan.org/dist/Net-SSLeay/'
  11 arch=('x86_64')
  12 license=('custom:BSD')
  13 depends=('openssl')
  14 makedepends=('chrpath')
  15 replaces=('net-ssleay')
  16 provides=('net-ssleay')
  17 options=('!emptydirs')
  18 source=(https://cpan.metacpan.org/authors/id/C/CH/CHRISN/${_cpanname}-${pkgver}.tar.gz)
  19 sha512sums=('e9d9161ebeb7be90f4c7a0ea98f1034892ce6d33aa72872683177b19daa1f4c5819f85ea9a052a076ec8d7c21705f6c344aef64680bc881bf3218d38e8b7b173')
  20 b2sums=('04d97860817b013a9680e0ef29b0004ddb98da2db859761a45612c4d25b6edd16bf92645293d1108d83352bce18665721c6df05455426b32a95a42b464119a3d')
  21
  22 build() {
  23   cd ${_cpanname}-${pkgver}
  24   PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  25   make
  26 }
  27
  28 check() {
  29   cd ${_cpanname}-${pkgver}
  30   make test
  31 }
  32
  33 package() {
  34   cd ${_cpanname}-${pkgver}
  35
  36   make install DESTDIR="${pkgdir}"
  37   install -Dm 644 README -t "${pkgdir}/usr/share/doc/${pkgname}"
  38   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  39
  40   # strip rpath
  41   find "${pkgdir}" -name '*.so' -exec chrpath -d '{}' \;
  42 }
  43
  44 # vim: ts=2 sw=2 et: