gupnp-dlna/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3
   4 pkgname=gupnp-dlna
   5 pkgver=0.12.0
   6 pkgrel=2
   7 pkgdesc="Library to ease DLNA-related bits for applications using gupnp"
   8 url="https://wiki.gnome.org/Projects/GUPnP"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(gst-plugins-base-libs)
  12 makedepends=(gobject-introspection gtk-doc vala meson git)
  13 _commit=cc09daae47ef0e030895edbeba58636c76f53b3d  # tags/gupnp-dlna-0.12.0^0
  14 source=("git+https://gitlab.gnome.org/GNOME/gupnp-dlna.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/^gupnp-dlna-//;s/[^-]*-g/r&/;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24 }
  25
  26 build() {
  27   arch-meson $pkgname build -D gtk_doc=true
  28   meson compile -C build
  29 }
  30
  31 check() {
  32   meson test -C build
  33 }
  34
  35 package() {
  36   depends+=(libg{lib,object}-2.0.so)
  37   provides+=(libgupnp-dlna{,-gst}-2.0.so)
  38
  39   meson install -C build --destdir "$pkgdir"
  40 }
  41
  42 # vim:set sw=2 sts=-1 et: