qtkeychain/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Kuba Serafinowski <zizzfizzix(at)gmail(dot)com>
   3 # Contributor: Teo Mrnjavac <teo@kde.org>
   4
   5 pkgbase=qtkeychain
   6 pkgname=(qtkeychain-qt5 qtkeychain-qt6)
   7 pkgver=0.13.2
   8 pkgrel=1
   9 pkgdesc='Provides support for secure credentials storage'
  10 arch=(x86_64)
  11 url='https://github.com/frankosterfeld/qtkeychain'
  12 license=(BSD)
  13 depends=(libsecret)
  14 makedepends=(cmake qt5-tools qt6-tools)
  15 source=(https://github.com/frankosterfeld/qtkeychain/archive/v$pkgver/$pkgname-$pkgver.tar.gz)
  16 sha256sums=('20beeb32de7c4eb0af9039b21e18370faf847ac8697ab3045906076afbc4caa5')
  17
  18 build() {
  19   cmake -B build-qt5 -S $pkgbase-$pkgver \
  20     -DCMAKE_INSTALL_PREFIX=/usr
  21   cmake --build build-qt5
  22
  23   cmake -B build-qt6 -S $pkgbase-$pkgver \
  24     -DCMAKE_INSTALL_PREFIX=/usr \
  25     -DBUILD_WITH_QT6=ON
  26   cmake --build build-qt6
  27 }
  28
  29 package_qtkeychain-qt5() {
  30   depends+=(qt5-base)
  31   optdepends=('kwallet: kwallet backend')
  32   conflicts=(qtkeychain)
  33   provides=(qtkeychain)
  34   replaces=(qtkeychain)
  35
  36   DESTDIR="$pkgdir" cmake --install build-qt5
  37   install -Dm644 $pkgbase-$pkgver/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  38 }
  39
  40 package_qtkeychain-qt6() {
  41   depends+=(qt6-base)
  42
  43   DESTDIR="$pkgdir" cmake --install build-qt6
  44   install -Dm644 $pkgbase-$pkgver/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  45 }