gcr/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgbase=gcr
   5 pkgname=(gcr gcr-docs)
   6 pkgver=3.41.1
   7 pkgrel=1
   8 pkgdesc="A library for bits of crypto UI and parsing"
   9 url="https://gitlab.gnome.org/GNOME/gcr"
  10 arch=(x86_64)
  11 license=(GPL2)
  12 depends=(gtk3 libgcrypt p11-kit openssh libsecret)
  13 makedepends=(gobject-introspection vala libxslt git gi-docgen meson)
  14 options=(debug)
  15 _commit=664f8d8619cc6d661bd863107824efbac383a9bf  # tags/3.41.1^0
  16 source=("git+https://gitlab.gnome.org/GNOME/gcr.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd gcr
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd gcr
  26 }
  27
  28 build() {
  29   arch-meson gcr build
  30   meson compile -C build
  31 }
  32
  33 check() {
  34   # Secure memory tests fail
  35   dbus-run-session meson test -C build --print-errorlogs || :
  36 }
  37
  38 package_gcr() {
  39   provides=(libgck-1.so libgcr-{base,ui}-3.so)
  40   backup=(etc/security/limits.d/10-gcr.conf)
  41   install=gcr.install
  42
  43   meson install -C build --destdir "$pkgdir"
  44
  45   # gcr wants to lock some memory to prevent swapping out private keys
  46   # https://bugs.archlinux.org/task/32616
  47   # https://bugzilla.gnome.org/show_bug.cgi?id=688161
  48   install -Dm644 /dev/stdin "$pkgdir/etc/security/limits.d/10-gcr.conf" <<END
  49 @users - memlock 1024
  50 END
  51
  52   mkdir -p doc/usr/share
  53   mv {"$pkgdir",doc}/usr/share/doc
  54 }
  55
  56 package_gcr-docs() {
  57   pkgdesc+=" (documentation)"
  58   depends=()
  59
  60   mv doc/* "$pkgdir"
  61 }
  62
  63 # vim:set sw=2 sts=-1 et: