glibmm-2.68/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Tom Newsom <Jeepster@gmx.co.uk>
   4
   5 pkgbase=glibmm-2.68
   6 pkgname=(glibmm-2.68 glibmm-2.68-docs)
   7 pkgver=2.72.1
   8 pkgrel=1
   9 pkgdesc="C++ bindings for GLib"
  10 url="https://www.gtkmm.org/"
  11 arch=(x86_64)
  12 license=(LGPL)
  13 depends=(glib2 libsigc++-3.0)
  14 makedepends=(git meson mm-common perl-xml-parser clang)
  15 checkdepends=(glib-networking)
  16 options=(!emptydirs debug)
  17 _commit=9b50d0c719b19461719fbc97d27055b82091a482  # tags/2.72.1^0
  18 source=("git+https://gitlab.gnome.org/GNOME/glibmm.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd glibmm
  23   git describe --tags | sed 's/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd glibmm
  28 }
  29
  30 build() {
  31   arch-meson glibmm build -D maintainer-mode=true
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   meson test -C build --print-errorlogs
  37 }
  38
  39 package_glibmm-2.68() {
  40   depends+=(libsigc-3.0.so)
  41   provides=(libglibmm-2.68.so)
  42
  43   meson install -C build --destdir "$pkgdir"
  44
  45   # Split -docs
  46   mkdir -p docs/usr/share
  47   mv -t docs/usr/share "$pkgdir"/usr/share/{devhelp,doc}
  48 }
  49
  50 package_glibmm-2.68-docs() {
  51   pkgdesc+=" (documentation)"
  52   depends=()
  53   options=(!strip)
  54
  55   mv -t "$pkgdir" docs/*
  56 }