imlib2/trunk/PKGBUILD

   1 # Maintainer: Ronald van Haren <ronald.archlinux.org>
   2 # Contributor: Arjan Timmerman <arjan.archlinux.org>
   3 # Contributor: Tom Newsom <Jeepster.gmx.co.uk>
   4
   5 pkgname=imlib2
   6 pkgver=1.9.1
   7 pkgrel=1
   8 pkgdesc='Library that does image file loading and saving as well as rendering, manipulation, arbitrary polygon support'
   9 url='https://sourceforge.net/projects/enlightenment/'
  10 arch=('x86_64')
  11 license=('BSD')
  12 options=('debug')
  13 makedepends=(# Currently highway does provide a static library only, that libjxl links to.
  14              # This introduces a build dependency for now...
  15              'highway'
  16              'libheif' 'libid3tag' 'libjxl' 'librsvg' 'libspectre' 'libwebp' 'openjpeg2')
  17 depends=('bzip2' 'freetype2' 'giflib' 'libjpeg-turbo' 'libpng' 'libtiff' 'libxext' 'xz')
  18 optdepends=('libheif: HEIF loader (for AVIF)'
  19             'libid3tag: ID3 loader'
  20             'libjxl: JXL loader'
  21             'librsvg: SVG loader'
  22             'libspectre: PS loader'
  23             'libwebp: WEBP loader'
  24             'openjpeg2: J2K loader')
  25 source=("https://downloads.sourceforge.net/project/enlightenment/imlib2-src/${pkgver}/${pkgname}-${pkgver}.tar.xz")
  26 sha256sums=('4a224038bfffbe5d4d250c44e05f4ee5ae24dcfef8395b1677c715c58f764d43')
  27 sha512sums=('00eb8804a32e1403614e9f899f358dd9797f4bcfa7e9fdecd37992731019933e39834a60bd20be8fb69a35161ba1e784bd638b5ecb626d01a4f69c70c330e5f1')
  28
  29 build() {
  30   cd "${pkgname}-${pkgver}"
  31
  32   ./configure \
  33     --prefix=/usr \
  34     --sysconfdir=/etc/imlib2 \
  35     --x-libraries=/usr/lib \
  36     --enable-amd64
  37   make
  38 }
  39
  40
  41 check() {
  42   cd "${pkgname}-${pkgver}"
  43   make check
  44 }
  45
  46
  47 package() {
  48   cd "${pkgname}-${pkgver}"
  49   make DESTDIR="${pkgdir}" install
  50
  51   # Install License
  52   install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
  53 }