java-common/repos/extra-any/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Guillaume ALAUX <guillaume@archlinux.org>
   3
   4 pkgbase=java-common
   5 pkgname=('java-runtime-common' 'java-environment-common')
   6 pkgver=3
   7 pkgrel=3
   8 pkgdesc='Common files for Java Runtime Environments'
   9 url='https://www.archlinux.org/packages/extra/any/java-common/'
  10 arch=('any')
  11 license=('GPL')
  12 makedepends=('bash' 'findutils' 'coreutils')
  13 checkdepends=('wget')
  14 _shunitver=2.1.7
  15 source=(profile_jre.csh
  16         profile_jre.sh
  17         bin_archlinux-java
  18         test_archlinux-java
  19         https://github.com/kward/shunit2/archive/v${_shunitver}/shunit2-${_shunitver}.tar.gz)
  20 sha256sums=('9d25638cafc2fabd1ba6f2f26aa01233eccf3d31db003d956b571f0ab655dd23'
  21             '519e9881a2a9f4fc3d581ea0ef0da594eedbfdfcf734f9fdc0bb595e8ac77e4c'
  22             '5101f9d3d42cd545843a537826451c1b2e0bf2b16aba4e36ac797d9ace16dc63'
  23             'f4c3fc55568fbbd298c1bf617bdd7f45db600b47c9991b072e409876e8cdd341'
  24             '41a103aa984bfdeea3fec426edb0b3dda19153a5ce448d4b4bbe52a85c4d7fee')
  25
  26 check() {
  27   ln -s shunit2-${_shunitver} shunit2
  28   ./test_archlinux-java
  29 }
  30
  31 package_java-runtime-common() {
  32   pkgdesc='Common files for Java Runtime Environments'
  33   backup=(etc/profile.d/jre.sh
  34           etc/profile.d/jre.csh)
  35   depends=('bash' 'findutils' 'coreutils')
  36   install=install_java-runtime-common.sh
  37
  38   install -d -m 755 "${pkgdir}/usr/lib/jvm/"
  39   ln -s /dev/null "${pkgdir}/usr/lib/jvm/default"
  40   ln -s /dev/null "${pkgdir}/usr/lib/jvm/default-runtime"
  41
  42   install -D -m 644 profile_jre.sh  "${pkgdir}/etc/profile.d/jre.sh"
  43   install -D -m 644 profile_jre.csh "${pkgdir}/etc/profile.d/jre.csh"
  44   install -D -m 755 bin_archlinux-java "${pkgdir}/usr/bin/archlinux-java"
  45
  46   install -d -m 755 "${pkgdir}/usr/bin/"
  47   # Official list of binaries that Java headless runtime packages MUST provide
  48   # This list is based on Arch Linux' default Java implementation: "OpenJDK 7 Icedtea"
  49   for b in \
  50     java keytool orbd pack200 rmid rmiregistry servertool tnameserv unpack200;
  51   do
  52     ln -s /usr/lib/jvm/default-runtime/bin/${b} "${pkgdir}/usr/bin/${b}"
  53   done
  54 }
  55
  56 package_java-environment-common() {
  57   pkgdesc='Common files for Java Development Kits'
  58
  59   install -d "${pkgdir}/usr/bin"
  60   # Official list of supplementary binaries that Java environment packages MUST provide
  61   # This list is based on Arch Linux' default Java implementation: "OpenJDK 7 Icedtea"
  62   for b in \
  63     jar jarsigner javac javadoc javah javap jcmd \
  64     jconsole jdb jinfo jmap jps jstack jstat \
  65     jstatd rmic schemagen serialver wsgen wsimport xjc;
  66   do
  67     ln -s /usr/lib/jvm/default/bin/${b} "${pkgdir}/usr/bin/${b}"
  68   done
  69 }
  70
  71 # vim: ts=2 sw=2 et: