java-hamcrest/repos/extra-any/PKGBUILD

   1 # Maintainer: Guillaume ALAUX <guillaume@archlinux.org>
   2 _libname=hamcrest
   3 pkgname=java-${_libname}
   4 pkgver=1.3
   5 pkgrel=5
   6 pkgdesc='Java matcher objects library'
   7 arch=('any')
   8 url='https://code.google.com/p/hamcrest'
   9 license=('BSD')
  10 depends=('java-runtime-headless')
  11 _url='https://storage.googleapis.com/google-code-archive-downloads/v2/code.google.com/hamcrest'
  12 source=(${_url}/${_libname}-core-${pkgver}.jar
  13         ${_url}/${_libname}-library-${pkgver}.jar
  14         ${_url}/${_libname}-generator-${pkgver}.jar
  15         ${_url}/${_libname}-integration-${pkgver}.jar
  16         LICENSE.txt)
  17 noextract=(${_libname}-core-${pkgver}.jar
  18            ${_libname}-library-${pkgver}.jar
  19            ${_libname}-generator-${pkgver}.jar
  20            ${_libname}-integration-${pkgver}.jar)
  21 sha256sums=('66fdef91e9739348df7a096aa384a5685f4e875584cce89386a7a47251c4d8e9'
  22             '711d64522f9ec410983bd310934296da134be4254a125080a0416ec178dfad1c'
  23             '84c810cafabd046d0e5599f9b5fc1514b2a6ce45313997e020a47076ba27d035'
  24             '70f418efbb506c5155da5f9a5a33262ea08a9e4d7fea186aa9015c41a7224ac2'
  25             '1cde867cab5c8e842929da5391cef98b4017314822270e934e8e2eef3767c666')
  26
  27 package() {
  28   cd "${srcdir}"
  29
  30   install -dm755 ${pkgdir}/usr/share/java/${_libname}
  31   for j in core library generator integration; do
  32     cp ${_libname}-${j}-${pkgver}.jar ${pkgdir}/usr/share/java/${_libname}/${j}-${pkgver}.jar
  33     ln -s ${j}-${pkgver}.jar ${pkgdir}/usr/share/java/${_libname}/${j}.jar
  34     ln -s ${_libname}/${j}-${pkgver}.jar ${pkgdir}/usr/share/java/${_libname}-${j}.jar
  35   done
  36
  37   install -Dm644 LICENSE.txt ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
  38 }