librsvg/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgbase=librsvg
   5 pkgname=(librsvg librsvg-docs)
   6 pkgver=2.54.4
   7 pkgrel=1
   8 epoch=2
   9 pkgdesc="SVG rendering library"
  10 url="https://wiki.gnome.org/Projects/LibRsvg"
  11 arch=(x86_64)
  12 license=(LGPL)
  13 depends=(cairo freetype2 gdk-pixbuf2 glib2 harfbuzz libxml2 pango)
  14 makedepends=(gobject-introspection vala git rust gi-docgen python-docutils)
  15 checkdepends=(ttf-dejavu)
  16 options=(debug)
  17 _commit=6539eef7be69c3f7089489c9a8f39d085e677bad  # tags/2.54.4^0
  18 source=("git+https://gitlab.gnome.org/GNOME/librsvg.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd librsvg
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd librsvg
  28   NOCONFIGURE=1 ./autogen.sh
  29 }
  30
  31 # Use LTO
  32 export CARGO_PROFILE_RELEASE_LTO=true CARGO_PROFILE_RELEASE_CODEGEN_UNITS=1
  33
  34 # Use debug
  35 export CARGO_PROFILE_RELEASE_DEBUG=2
  36
  37 build() {
  38   cd librsvg
  39   ./configure --prefix=/usr --disable-static --enable-vala --enable-gtk-doc
  40   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' libtool
  41   make
  42 }
  43
  44 check() {
  45   # Test suite is very dependent on the versions of
  46   # Cairo, Pango, FreeType and HarfBuzz
  47   make -C librsvg check || :
  48 }
  49
  50 package_librsvg() {
  51   provides=(librsvg-${pkgver%%.*}.so)
  52
  53   make -C librsvg DESTDIR="$pkgdir" install
  54
  55   mkdir -p doc/usr/share
  56   mv {"$pkgdir",doc}/usr/share/doc
  57 }
  58
  59 package_librsvg-docs() {
  60   pkgdesc+=" (documentation)"
  61   depends=()
  62
  63   mv doc/* "$pkgdir"
  64 }
  65
  66 # vim:set sw=2 et: