libusb/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Tobias Powalowski <tpowa@archlinux.org>
   4
   5 pkgname=libusb
   6 pkgver=1.0.26
   7 pkgrel=1
   8 pkgdesc="Library that provides generic access to USB devices"
   9 arch=(x86_64)
  10 url="https://libusb.info/"
  11 license=(LGPL2.1)
  12 depends=(glibc)
  13 makedepends=(systemd)
  14 provides=(libusb-1.0.so)
  15 options=(debug)
  16 source=(https://github.com/$pkgname/$pkgname/releases/download/v$pkgver/$pkgname-$pkgver.tar.bz2)
  17 sha512sums=('fcdb85c98f21639668693c2fd522814d440972d65883984c4ae53d0555bdbdb7e8c7a32199cd4b01113556a1eb5be7841b750cc73c9f6bda79bfe1af80914e71')
  18 b2sums=('0cc397ecf4de0066abbff9b286a9e4fcd48658698d5e0d6b736abf56b48c1b55a05f15fff7be53fd33f767621e0c25d87275a47e05a4bcb44c4b8ac9221cd081')
  19
  20 prepare() {
  21   cd $pkgname-$pkgver
  22   autoreconf -fiv
  23 }
  24
  25 build() {
  26   cd $pkgname-$pkgver
  27   ./configure --prefix=/usr
  28   make
  29 }
  30
  31 check() {
  32   make -k check -C $pkgname-$pkgver
  33 }
  34
  35 package () {
  36   depends+=(libudev.so)
  37
  38   make DESTDIR="$pkgdir" install -C $pkgname-$pkgver
  39   install -vDm 644 $pkgname-$pkgver/{AUTHORS,ChangeLog,README} -t "$pkgdir/usr/share/doc/$pkgname/"
  40 }