python-numpy/trunk/PKGBUILD

   1 # Maintainer: Jan de Groot <jgc@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3 # Contributor: Douglas Soares de Andrade <dsa@aur.archlinux.org>
   4 # Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
   5
   6 pkgname=python-numpy
   7 pkgver=1.23.1
   8 pkgrel=1
   9 pkgdesc="Scientific tools for Python"
  10 arch=('x86_64')
  11 license=('custom')
  12 url="https://www.numpy.org/"
  13 depends=('cblas' 'lapack' 'python')
  14 optdepends=('openblas: faster linear algebra')
  15 makedepends=('python-setuptools' 'gcc-fortran' 'cython')
  16 checkdepends=('python-pytest' 'python-hypothesis')
  17 options=('staticlibs')
  18 source=("https://github.com/numpy/numpy/releases/download/v$pkgver/numpy-$pkgver.tar.gz")
  19 sha512sums=('b34fb627e0e548bae3cf4555c4c71ab4a170ade86a9ff4011a5dfac6aba29e2e04b1151b9364cd1efff004efc1c04b3bab111facbcdc3297f8c38d7a09c83e17')
  20
  21 build() {
  22   cd numpy-$pkgver
  23   python setup.py build
  24 }
  25
  26 check() {
  27   cd numpy-$pkgver
  28   python setup.py install --root="$PWD/tmp_install" --optimize=1
  29   cd "$PWD/tmp_install"
  30   PATH="$PWD/usr/bin:$PATH" PYTHONPATH="$PWD/usr/lib/python3.10/site-packages:$PYTHONPATH" python -c 'import numpy; numpy.test()'
  31 }
  32
  33 package() {
  34   cd numpy-$pkgver
  35   python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
  36
  37   install -D -m644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/python-numpy/
  38 }