qt6-webengine/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3
   4 pkgname=qt6-webengine
   5 _qtver=6.3.1
   6 pkgver=${_qtver/-/}
   7 pkgrel=1
   8 arch=(x86_64)
   9 url='https://www.qt.io'
  10 license=(GPL3 LGPL3 FDL custom)
  11 pkgdesc='Provides support for web applications using the Chromium browser project'
  12 depends=(qt6-webchannel qt6-positioning libxcomposite libxrandr libxkbfile
  13          libevent snappy nss libxslt minizip ffmpeg re2 libvpx libxtst ttf-font pciutils)
  14 makedepends=(cmake ninja python-html5lib gperf jsoncpp qt6-tools pipewire nodejs qt6-websockets)
  15 optdepends=('pipewire: WebRTC desktop sharing under Wayland')
  16 groups=(qt6)
  17 options=(debug)
  18 _pkgfn=${pkgname/6-/}-everywhere-src-$_qtver
  19 source=(https://download.qt.io/official_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
  20 sha256sums=('ad7a33b21a956deda37c587d50f821ca3816403ae31ba9b5d59d01561ad66e47')
  21
  22 build() {
  23   cmake -B build -S $_pkgfn -G Ninja \
  24     -DCMAKE_TOOLCHAIN_FILE=/usr/lib/cmake/Qt6/qt.toolchain.cmake \
  25     -DQT_FEATURE_webengine_system_ffmpeg=ON \
  26     -DQT_FEATURE_webengine_system_icu=ON \
  27     -DQT_FEATURE_webengine_system_libevent=ON \
  28     -DQT_FEATURE_webengine_system_libxslt=ON \
  29     -DQT_FEATURE_webengine_proprietary_codecs=ON \
  30     -DQT_FEATURE_webengine_kerberos=ON \
  31     -DQT_FEATURE_webengine_webrtc_pipewire=ON \
  32     -DQT_FEATURE_webengine_full_debug_info=ON
  33   cmake --build build
  34 }
  35
  36 package() {
  37   DESTDIR="$pkgdir" cmake --install build
  38
  39   install -Dm644 "$srcdir"/${_pkgfn}/src/3rdparty/chromium/LICENSE "$pkgdir"/usr/share/licenses/${pkgname}/LICENSE.chromium
  40 }