transmission/trunk/PKGBUILD

   1 # Maintainer : Tom Gundersen <teg@jklm.no>
   2 # Maintainer : Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgbase=transmission
   5 pkgname=(transmission-cli transmission-gtk transmission-qt libtransmission)
   6 pkgver=3.00
   7 pkgrel=4
   8 arch=(x86_64)
   9 url="http://www.transmissionbt.com/"
  10 license=(MIT)
  11 makedepends=(gtk3 intltool curl qt5-base libevent systemd qt5-tools libappindicator-gtk3 dht libb64 libutp miniupnpc libnatpmp)
  12 source=(https://github.com/transmission/transmission-releases/raw/master/transmission-${pkgver}.tar.xz
  13         transmission-cli.sysusers
  14         transmission-cli.tmpfiles)
  15 sha256sums=('9144652fe742f7f7dd6657716e378da60b751aaeda8bef8344b3eefc4db255f2'
  16             '641310fb0590d40e00bea1b5b9c843953ab78edf019109f276be9c6a7bdaf5b2'
  17             '1266032bb07e47d6bcdc7dabd74df2557cc466c33bf983a5881316a4cc098451')
  18
  19 prepare() {
  20   cd $pkgbase-$pkgver
  21
  22 # Fix build with autoconf 2.70
  23   sed -i 's/\[IT_PROG_INTLTOOL(\[/[\nIT_PROG_INTLTOOL(\[/' configure.ac
  24   rm -f m4/glib-gettext.m4
  25   autoreconf -fi
  26
  27   sed -i '/^Icon=/ s/$/-qt/' qt/transmission-qt.desktop
  28 }
  29
  30 build() {
  31   export CFLAGS+=" -ffat-lto-objects"
  32   cd $pkgbase-$pkgver
  33   ./configure --prefix=/usr \
  34     --enable-external-dht \
  35     --enable-external-b64 \
  36     --enable-external-natpmp
  37   make
  38
  39   cd qt
  40   qmake qtr.pro \
  41     DEFINES+=TRANSLATIONS_DIR=\\\\\\\"/usr/share/transmission-qt/translations\\\\\\\"
  42   make
  43   lrelease translations/*.ts
  44 }
  45
  46 package_transmission-cli() {
  47   pkgdesc='Fast, easy, and free BitTorrent client (CLI tools, daemon and web client)'
  48   depends=(curl libevent systemd libb64 miniupnpc libnatpmp)
  49
  50   cd $pkgbase-$pkgver
  51
  52   for dir in daemon cli web utils; do
  53     make -C "$dir" DESTDIR="$pkgdir" install
  54   done
  55
  56   install -Dm644 daemon/transmission-daemon.service \
  57     "$pkgdir/usr/lib/systemd/system/transmission.service"
  58   install -Dm644 COPYING "$pkgdir/usr/share/licenses/transmission-cli/COPYING"
  59
  60   install -Dm644 "$srcdir/$pkgname.sysusers" \
  61     "$pkgdir/usr/lib/sysusers.d/transmission.conf"
  62   install -Dm644 "$srcdir/$pkgname.tmpfiles" \
  63     "$pkgdir/usr/lib/tmpfiles.d/transmission.conf"
  64 }
  65
  66 package_transmission-gtk() {
  67   pkgdesc='Fast, easy, and free BitTorrent client (GTK+ GUI)'
  68   depends=(curl libevent gtk3 hicolor-icon-theme libappindicator-gtk3 libb64 miniupnpc libnatpmp)
  69   optdepends=('libnotify: Desktop notification support'
  70               'transmission-cli: daemon and web support')
  71
  72   cd $pkgbase-$pkgver
  73
  74   make -C gtk DESTDIR="$pkgdir" install
  75   make -C po DESTDIR="$pkgdir" install
  76   install -Dm644 COPYING "$pkgdir/usr/share/licenses/transmission-gtk/COPYING"
  77 }
  78
  79 package_transmission-qt() {
  80   pkgdesc='Fast, easy, and free BitTorrent client (Qt GUI)'
  81   depends=(curl qt5-base libevent libb64 miniupnpc libnatpmp)
  82   optdepends=('transmission-cli: daemon and web support')
  83
  84   cd $pkgbase-$pkgver
  85
  86   make -C qt INSTALL_ROOT="$pkgdir"/usr install
  87   install -Dm644 -t "$pkgdir/usr/share/transmission-qt/translations" \
  88     qt/translations/*.qm
  89
  90   install -Dm644 COPYING "$pkgdir/usr/share/licenses/transmission-qt/COPYING"
  91   install -Dm644 qt/icons/transmission.png \
  92     "$pkgdir/usr/share/pixmaps/transmission-qt.png"
  93   install -Dm644 qt/transmission-qt.desktop \
  94     "$pkgdir/usr/share/applications/transmission-qt.desktop"
  95 }
  96
  97 package_libtransmission() {
  98   pkgdesc='Fast, easy, and free BitTorrent client (shared library)'
  99
 100   cd $pkgbase-$pkgver
 101   install -Dm644 libtransmission/libtransmission.a -t "$pkgdir"/usr/lib
 102   install -Dm644 libtransmission/*.h -t "$pkgdir"/usr/include/transmission
 103   install -Dm644 COPYING "$pkgdir/usr/share/licenses/libtransmission/COPYING"
 104 }