endeavour/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=endeavour
   4 pkgver=43.0
   5 pkgrel=2
   6 pkgdesc="Personal task manager (Formerly GNOME Todo)"
   7 url="https://wiki.gnome.org/Apps/Todo"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(
  11   evolution-data-server
  12   gtk4
  13   libadwaita
  14   libpeas
  15   python
  16 )
  17 makedepends=(
  18   appstream-glib
  19   git
  20   gobject-introspection
  21   meson
  22   yelp-tools
  23 )
  24 provides=(gnome-todo)
  25 replaces=("gnome-todo<=41.0+r106+gebc68374-1")
  26 conflicts=("gnome-todo<=41.0+r106+gebc68374-1")
  27 groups=(gnome-extra)
  28 _commit=92706b42784e553d9f841117111a5e14bd201e1c  # tags/43.0^0
  29 source=("git+https://gitlab.gnome.org/World/Endeavour.git#commit=$_commit")
  30 b2sums=('SKIP')
  31
  32 pkgver() {
  33   cd Endeavour
  34   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  35 }
  36
  37 prepare() {
  38   cd Endeavour
  39 }
  40
  41 build() {
  42   arch-meson Endeavour build
  43   meson compile -C build
  44 }
  45
  46 check() (
  47   export GSETTINGS_SCHEMA_DIR="$PWD/Endeavour/data"
  48   glib-compile-schemas "$GSETTINGS_SCHEMA_DIR"
  49
  50   meson test -C build --print-errorlogs
  51 )
  52
  53 package() {
  54   meson install -C build --destdir "$pkgdir"
  55 }
  56
  57 # vim:set sw=2 sts=-1 et: