gnome-dictionary/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=gnome-dictionary
   5 pkgver=40.0
   6 pkgrel=2
   7 pkgdesc="Look up words in dictionary sources"
   8 url="https://wiki.gnome.org/Apps/Dictionary"
   9 arch=(x86_64)
  10 license=(GPL2)
  11 depends=(gtk3)
  12 makedepends=(
  13   appstream-glib
  14   git
  15   meson
  16   yelp-tools
  17 )
  18 groups=(gnome-extra)
  19 _commit=c37edfc2cbf91d6bae6d5264d0dcfcb5dd34b313  # tags/40.0^0
  20 source=("git+https://gitlab.gnome.org/GNOME/gnome-dictionary.git#commit=$_commit")
  21 b2sums=('SKIP')
  22
  23 pkgver() {
  24   cd $pkgname
  25   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  26 }
  27
  28 prepare() {
  29   cd $pkgname
  30
  31   # Fix build with newer meson
  32   git cherry-pick -n 87c026cfe4acbcfc62d15950f88a71d8d9678c7e \
  33                      cf3f8a67cd6f3059c555ed9cf0f5fba10abb7f68
  34 }
  35
  36 build() {
  37   arch-meson $pkgname build
  38   meson compile -C build
  39 }
  40
  41 check() {
  42   meson test -C build --print-errorlogs
  43 }
  44
  45 package() {
  46   meson install -C build --destdir "$pkgdir"
  47 }
  48
  49 # vim:set sw=2 sts=-1 et: