htop/trunk/PKGBUILD

   1 # Maintainer: Christian Hesse <mail@eworm.de>
   2 # Maintainer: Angel Velasquez <angvp@archlinux.org>
   3 # Contributor: Eric Belanger <eric@archlinux.org>
   4 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   5
   6 pkgname=htop
   7 _tag='4dbd0b5c87f4225495d6e0591a1d7227f120ead1' # git rev-parse ${pkgver}
   8 pkgver=3.2.2
   9 pkgrel=1
  10 pkgdesc='Interactive process viewer'
  11 arch=('x86_64')
  12 url='https://htop.dev/'
  13 license=('GPL')
  14 depends=('libcap' 'libcap.so' 'libnl' 'ncurses' 'libncursesw.so')
  15 makedepends=('git' 'lm_sensors')
  16 optdepends=('lm_sensors: show cpu temperatures'
  17             'lsof: show files opened by a process'
  18             'strace: attach to a running process')
  19 options=('!emptydirs')
  20 validpgpkeys=('F7ABE8761E6FE68638E6283AFE0842EE36DD8C0C'  # Nathan Scott <nathans@debian.org>
  21               '0D316B6ABE022C7798D0324BF1D35CB9E8E12EAD') # Benny Baumann <BenBE@geshi.org>
  22 source=("git+https://github.com/htop-dev/htop.git#tag=${_tag}?signed")
  23 sha256sums=('SKIP')
  24
  25 prepare() {
  26   cd "${pkgname}"
  27
  28   autoreconf -fi
  29 }
  30
  31 build() {
  32   cd "${pkgname}"
  33
  34   ./configure \
  35       --prefix=/usr \
  36       --sysconfdir=/etc \
  37       --enable-affinity \
  38       --enable-capabilities \
  39       --enable-delayacct \
  40       --enable-openvz \
  41       --enable-sensors \
  42       --enable-unicode \
  43       --enable-vserver
  44
  45   make
  46 }
  47
  48 package() {
  49   cd "${pkgname}"
  50
  51   make DESTDIR="${pkgdir}" install
  52 }