libmbim/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=libmbim
   4 pkgver=1.28.4
   5 pkgrel=1
   6 pkgdesc="MBIM modem protocol helper library"
   7 url="https://www.freedesktop.org/wiki/Software/libmbim/"
   8 arch=(x86_64)
   9 license=(GPL2)
  10 depends=(glib2 bash systemd)
  11 makedepends=(gtk-doc meson git help2man gobject-introspection bash-completion)
  12 provides=(libmbim-glib.so)
  13 _commit=7f1c7907c4654ba5c619a635cef5475ca161d027  # tags/1.28.4^0
  14 source=("git+https://gitlab.freedesktop.org/mobile-broadband/libmbim.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd libmbim
  19   git describe --tags | sed 's/-rc/rc/;s/[^-]*-g/r&/;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd libmbim
  24 }
  25
  26 build() {
  27   arch-meson libmbim build -D gtk_doc=true
  28   meson compile -C build
  29 }
  30
  31 check() {
  32   meson test -C build --print-errorlogs
  33 }
  34
  35 package() {
  36   meson install -C build --destdir "$pkgdir"
  37 }
  38
  39 # vim:set sw=2 sts=-1 et: