networkmanager-openvpn/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=networkmanager-openvpn
   5 pkgver=1.10.2
   6 pkgrel=1
   7 pkgdesc="NetworkManager VPN plugin for OpenVPN"
   8 url="https://wiki.gnome.org/Projects/NetworkManager"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(libnm libsecret openvpn)
  12 makedepends=(libnma libnma-gtk4 python git)
  13 optdepends=('libnma: GUI support (GTK 3)'
  14             'libnma-gtk4: GUI support (GTK 4)')
  15 _commit=ae9575dd07cc2d2d51ec8d0297823e07017cb6e6  # tags/1.10.2^0
  16 source=("git+https://gitlab.gnome.org/GNOME/NetworkManager-openvpn.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd NetworkManager-openvpn
  21   git describe --tags | sed 's/-dev/dev/;s/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd NetworkManager-openvpn
  26   autoreconf -fvi
  27 }
  28
  29 build() {
  30   cd NetworkManager-openvpn
  31   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  32     --libexecdir=/usr/lib --disable-static --with-gtk4
  33   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  34   make
  35 }
  36
  37 package() {
  38   cd NetworkManager-openvpn
  39   make DESTDIR="$pkgdir" install dbusservicedir=/usr/share/dbus-1/system.d
  40   echo 'u nm-openvpn - "NetworkManager OpenVPN"' |
  41     install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
  42 }
  43
  44 # vim:set sw=2 sts=-1 et: