serf/trunk/PKGBUILD

   1 # Maintainer: Angel Velasquez <angvp@archlinux.org>
   2 # Contributor: Stéphane Gaudreault <stephane@archlinux.org>
   3
   4 pkgname=serf
   5 pkgver=1.3.9
   6 pkgrel=8
   7 pkgdesc="High-performance asynchronous HTTP client library"
   8 arch=('x86_64')
   9 url="https://serf.apache.org"
  10 license=('Apache')
  11 depends=('apr-util')
  12 makedepends=('scons')
  13 source=(https://www.apache.org/dist/serf/${pkgname}-${pkgver}.tar.bz2{,.asc}
  14         scons-python3.patch
  15         openssl3-ERR_GET_FUNC.patch
  16         openssl3-BIO_ctrl.patch)
  17 validpgpkeys=('C236283C970D2C3CFEEB4936BF35CF0078383142')
  18 sha256sums=('549c2d21c577a8a9c0450facb5cca809f26591f048e466552240947bdf7a87cc'
  19             'SKIP'
  20             '363732546098b4c9415eb5d38b595d04c660c6324a34159768d334507b7d241f'
  21             '15026f5ce219d2222dbdb6dcbb8911f3c8fbe0cedf3a2ec2ff434dde8d7fb9be'
  22             'bf30b79aff5b058ba3852930dad4e5c16fc2e2d76810ca80e6e22e3c8121cff6')
  23
  24 prepare() {
  25   cd $pkgname-$pkgver
  26   patch -p1 -i ../scons-python3.patch
  27   patch -p1 -i ../openssl3-ERR_GET_FUNC.patch
  28   patch -p1 -i ../openssl3-BIO_ctrl.patch
  29 }
  30
  31 build() {
  32   cd ${pkgname}-${pkgver}
  33   scons CFLAGS="${CFLAGS}" \
  34         LINKFLAGS="${LDFLAGS}" \
  35         PREFIX=/usr GSSAPI=/usr/bin/krb5-config
  36 }
  37
  38 check() {
  39   cd ${pkgname}-${pkgver}
  40   # Runs into infinite loop
  41   #scons check
  42 }
  43
  44 package() {
  45   cd ${pkgname}-${pkgver}
  46   install -d "${pkgdir}/usr"
  47   scons install --install-sandbox="${pkgdir}"
  48 }