swig/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Stéphane Gaudreault <stephane@archlinux.org>
   3 # Contributor: Tom Newsom <Jeepster@gmx.co.uk>
   4
   5 pkgname=swig
   6 pkgver=4.1.1
   7 pkgrel=2
   8 pkgdesc="Generate scripting interfaces to C/C++ code"
   9 arch=('x86_64')
  10 url="http://www.swig.org/"
  11 license=('custom')
  12 depends=('pcre2' 'gcc-libs')
  13 checkdepends=('ruby' 'python' 'java-environment' 'tcl' 'php' 'lua' 'r' 'go' 'boost')
  14 source=(https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.gz)
  15 sha512sums=('1cea1918455a75ebc9b2653dd1715bd5dcd974554955f324295c6a6f14c0a715651b221b85fad4a8af5197e0c75bfe7b590bc6ba7178c26245fbbd9a7e110100')
  16
  17 build() {
  18   cd ${pkgname}-${pkgver}
  19   ./configure --prefix=/usr
  20   make
  21 }
  22
  23 check() {
  24   cd ${pkgname}-${pkgver}
  25   make check PY3=y
  26 }
  27
  28 package() {
  29   cd ${pkgname}-${pkgver}
  30   make DESTDIR="${pkgdir}" install
  31   install -D -m644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
  32   install -D -m644 LICENSE-UNIVERSITIES "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE-UNIVERSITIES
  33 }