xapian-core/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: David Runge <dvzrv@archlinux.org>
   3 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   4 # Contributor: Alexander Fehr <pizzapunk gmail com>
   5 # Contributor: William Rea <sillywilly@gmail.com>
   6 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   7
   8 pkgname=xapian-core
   9 pkgver=1.4.22
  10 pkgrel=1
  11 epoch=1
  12 pkgdesc='Open source search engine library.'
  13 arch=('x86_64')
  14 url="https://www.xapian.org/"
  15 license=('GPL2')
  16 makedepends=('util-linux')
  17 depends=('bash' 'gcc-libs' 'glibc' 'zlib')
  18 provides=('libxapian.so')
  19 # xapian config requires libxapian.la
  20 options=('libtool')
  21 source=("https://oligarchy.co.uk/xapian/${pkgver}/${pkgname}-${pkgver}.tar.xz"{,.asc})
  22 sha512sums=('60d66adbacbd59622d25e392060984bd1dc6c870f9031765f54cb335fb29f72f6d006d27af82a50c8da2cfbebd08dac4503a8afa8ad51bc4e6fa9cb367a59d29'
  23             'SKIP')
  24 b2sums=('f4aec86cd5f63f6f1825a4f8f427ea23be2092ffb4ca11a2fdf20bdf652e7b9f768b1155bcf7ee5e5c5313206c92e1725d1b4d562e3074539a2e8f9901c44f8e'
  25         'SKIP')
  26 validpgpkeys=('08E2400FF7FE8FEDE3ACB52818147B073BAD2B07') # Olly Betts <olly@debian.org>
  27
  28 prepare() {
  29   cd "${pkgname}-${pkgver}"
  30   autoreconf -vfi
  31 }
  32
  33 build() {
  34   cd "${pkgname}-${pkgver}"
  35
  36   # workaround for test failure in libzim
  37   #   23/27 search_iterator  FAIL  0.47s  killed by signal 6 SIGABRT
  38   CXXFLAGS=${CXXFLAGS/-Wp,-D_GLIBCXX_ASSERTIONS}
  39
  40   ./configure --prefix=/usr
  41   make
  42 }
  43
  44 check() {
  45   cd "${pkgname}-${pkgver}"
  46   make check
  47 }
  48
  49 package() {
  50   depends+=('libuuid.so')
  51   cd ${pkgname}-${pkgver}
  52   make DESTDIR="${pkgdir}" install
  53   install -vDm 644 {AUTHORS,ChangeLog,HACKING,NEWS,README} \
  54     -t "${pkgdir}/usr/share/doc/${pkgname}"
  55 }