eog-plugins/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=eog-plugins
   4 pkgver=44.0
   5 pkgrel=1
   6 pkgdesc="Plugins for Eye of Gnome"
   7 url="https://wiki.gnome.org/Apps/EyeOfGnome/Plugins"
   8 arch=(x86_64)
   9 license=(GPL2)
  10 depends=(
  11   eog
  12   libchamplain
  13   libgdata
  14   python-gobject
  15 )
  16 makedepends=(
  17   git
  18   gobject-introspection
  19   meson
  20 )
  21 _commit=41f9d7d597cbd7423b186ab443b34a3e0feb9e94  # tags/44.0^0
  22 source=("git+https://gitlab.gnome.org/GNOME/eog-plugins.git#commit=$_commit")
  23 b2sums=('SKIP')
  24
  25 pkgver() {
  26   cd $pkgname
  27   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  28 }
  29
  30 prepare() {
  31   cd $pkgname
  32 }
  33
  34 build() {
  35   arch-meson $pkgname build
  36   meson compile -C build
  37 }
  38
  39 check() {
  40   meson test -C build --print-errorlogs
  41 }
  42
  43 package() {
  44   meson install -C build --destdir "$pkgdir"
  45 }
  46
  47 # vim:set sw=2 sts=-1 et: