webrtc-audio-processing/trunk/PKGBUILD-1.0

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=webrtc-audio-processing
   4 pkgver=1.0+20+ge31340c
   5 pkgrel=1
   6 pkgdesc="AudioProcessing library based on Google's implementation of WebRTC"
   7 url="https://freedesktop.org/software/pulseaudio/webrtc-audio-processing/"
   8 arch=(x86_64)
   9 license=(custom)
  10 depends=(gcc-libs)
  11 makedepends=(git meson abseil-cpp)
  12 provides=(libwebrtc-audio-{coding,processing}-${pkgver%%.*}.so)
  13 _commit=e31340c243f034e26e1e876f3f32fc842f5e5b5b  # master
  14 source=("git+https://gitlab.freedesktop.org/pulseaudio/webrtc-audio-processing.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/^v//;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24 }
  25
  26 build() {
  27   arch-meson $pkgname build \
  28     -D cpp_std=c++17  # must match abseil
  29   meson compile -C build
  30 }
  31
  32 check() {
  33   meson test -C build --print-errorlogs
  34 }
  35
  36 package() {
  37   meson install -C build --destdir "$pkgdir"
  38   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname/COPYING
  39 }
  40
  41 # vim:set sw=2 et: