gnome-logs/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gnome-logs
   4 pkgver=43.0
   5 pkgrel=1
   6 pkgdesc="A log viewer for the systemd journal"
   7 url="https://wiki.gnome.org/Apps/Logs"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(systemd gtk4 libadwaita gsettings-desktop-schemas)
  11 makedepends=(appstream-glib git meson yelp-tools)
  12 groups=(gnome)
  13 options=(debug)
  14 _commit=3fa0b8a7f734e6adf865cc5df673f6a74809b56d  # tags/43.0^0
  15 source=("git+https://gitlab.gnome.org/GNOME/gnome-logs.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/^gnome-logs-//;s/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25 }
  26
  27 build() {
  28   local meson_options=(
  29     -D man=true
  30   )
  31
  32   arch-meson $pkgname build "${meson_options[@]}"
  33   meson compile -C build
  34 }
  35
  36 check() {
  37   meson test -C build --print-errorlogs
  38 }
  39
  40 package() {
  41   meson install -C build --destdir "$pkgdir"
  42 }
  43
  44 # vim:set sw=2 sts=-1 et: