php-legacy/trunk/PKGBUILD

   1 # Maintainer: Pierre Schmitz <pierre@archlinux.de>
   2
   3 pkgbase=php-legacy
   4 pkgname=('php-legacy'
   5          'php-legacy-cgi'
   6          'php-legacy-apache'
   7          'php-legacy-fpm'
   8          'php-legacy-embed'
   9          'php-legacy-phpdbg'
  10          'php-legacy-dblib'
  11          'php-legacy-enchant'
  12          'php-legacy-gd'
  13          'php-legacy-intl'
  14          'php-legacy-sodium'
  15          'php-legacy-odbc'
  16          'php-legacy-pgsql'
  17          'php-legacy-pspell'
  18          'php-legacy-snmp'
  19          'php-legacy-sqlite'
  20          'php-legacy-tidy'
  21          'php-legacy-xsl')
  22 pkgver=8.1.13
  23 pkgrel=1
  24 arch=('x86_64')
  25 license=('PHP')
  26 url='https://www.php.net/'
  27 makedepends=('apache' 'aspell' 'gdbm' 'enchant' 'gd' 'gmp' 'icu' 'libsodium' 'libxslt' 'libzip' 'net-snmp'
  28              'postgresql-libs' 'sqlite' 'systemd' 'tidy' 'unixodbc' 'curl' 'libtool' 'postfix' 'freetds' 'pcre2' 'libnsl'
  29              'oniguruma')
  30 checkdepends=('procps-ng')
  31 options=('debug')
  32 source=("https://php.net/distributions/php-${pkgver}.tar.xz"{,.asc}
  33         'apache.patch' 'apache.conf' 'php-fpm.patch' 'php-fpm.tmpfiles' 'php.ini.patch' 'php-legacy.patch')
  34 sha256sums=('b15ef0ccdd6760825604b3c4e3e73558dcf87c75ef1d68ef4289d8fd261ac856'
  35             'SKIP'
  36             '702b163c66c65af92dcad8d79f41bda84bcd5d863235fcf1497c33a86db9e4ca'
  37             '2173046ac22ac50c7a6721306d3f79b2086f66a7a6ff5d8af249a474763197a1'
  38             '632aaa2e87f7d687b0b55a6a89e473d57891fdb0d20eef1b7733dabc02b78ba8'
  39             'f3236ca866095d5e42e51e3fa600082ccd0afcfb7f1aecbeb286ef9d4f0dd564'
  40             '789e88053846996e3a3f9e02355ce51de13456318ea5a9d6cb71b05b742549ab'
  41             'a1859005c9fad835079470e6fb3c0721b9bd024c8f3ae1f34cb082ec41c63194')
  42 validpgpkeys=('F1F692238FBC1666E5A5CCD4199F9DFEF6FFBAFD'
  43               '39B641343D8C104B2B146DC3F9C39DC0B9698544')
  44 _interpreter=${pkgver%.*}
  45
  46 prepare() {
  47         cd "${srcdir}/php-${pkgver}"
  48
  49         patch -p0 -i "${srcdir}/apache.patch"
  50         patch -p0 -i "${srcdir}/php-fpm.patch"
  51         patch -p0 -i "${srcdir}/php.ini.patch"
  52         patch -p0 -i "${srcdir}/php-legacy.patch"
  53         autoconf
  54
  55         # Disable failing tests
  56         rm tests/output/stream_isatty_*.phpt
  57         rm Zend/tests/arginfo_zpp_mismatch*.phpt
  58 }
  59
  60 build() {
  61         local _phpconfig="--srcdir=../php-${pkgver} \
  62                 --config-cache \
  63                 --prefix=/usr \
  64                 --sbindir=/usr/bin \
  65                 --sysconfdir=/etc/php-legacy \
  66                 --localstatedir=/var \
  67                 --with-layout=GNU \
  68                 --with-config-file-path=/etc/php-legacy \
  69                 --with-config-file-scan-dir=/etc/php-legacy/conf.d \
  70                 --disable-rpath \
  71                 --mandir=/usr/share/man \
  72                 --libdir=/usr/lib/php-legacy \
  73                 --datarootdir=/usr/share/php-legacy \
  74                 --datadir=/usr/share/php-legacy \
  75                 --program-suffix=-legacy \
  76                 --includedir=/usr/include/php-legacy \
  77                 --disable-gcc-global-regs \
  78                 "
  79
  80         local _phpextensions="\
  81                 --enable-bcmath=shared \
  82                 --enable-calendar=shared \
  83                 --enable-dba=shared \
  84                 --enable-exif=shared \
  85                 --enable-ftp=shared \
  86                 --enable-gd=shared \
  87                 --enable-intl=shared \
  88                 --enable-mbstring \
  89                 --enable-pcntl \
  90                 --enable-shmop=shared \
  91                 --enable-soap=shared \
  92                 --enable-sockets=shared \
  93                 --enable-sysvmsg=shared \
  94                 --enable-sysvsem=shared \
  95                 --enable-sysvshm=shared \
  96                 --with-bz2=shared \
  97                 --with-curl=shared \
  98                 --with-enchant=shared \
  99                 --with-external-gd \
 100                 --with-external-pcre \
 101                 --with-ffi=shared \
 102                 --with-gdbm \
 103                 --with-gettext=shared \
 104                 --with-gmp=shared \
 105                 --with-iconv=shared \
 106                 --with-kerberos \
 107                 --with-ldap=shared \
 108                 --with-ldap-sasl \
 109                 --with-mhash \
 110                 --with-mysql-sock=/run/mysqld/mysqld.sock \
 111                 --with-mysqli=shared,mysqlnd \
 112                 --with-openssl \
 113                 --with-password-argon2 \
 114                 --with-pdo-dblib=shared,/usr \
 115                 --with-pdo-mysql=shared,mysqlnd \
 116                 --with-pdo-odbc=shared,unixODBC,/usr \
 117                 --with-pdo-pgsql=shared \
 118                 --with-pdo-sqlite=shared \
 119                 --with-pgsql=shared \
 120                 --with-pspell=shared \
 121                 --with-readline \
 122                 --with-snmp=shared \
 123                 --with-sodium=shared \
 124                 --with-sqlite3=shared \
 125                 --with-tidy=shared \
 126                 --with-unixODBC=shared \
 127                 --with-xsl=shared \
 128                 --with-zip=shared \
 129                 --with-zlib \
 130                 "
 131
 132         EXTENSION_DIR=/usr/lib/php-legacy/modules
 133         export EXTENSION_DIR
 134
 135         mkdir "${srcdir}/build"
 136         cd "${srcdir}/build"
 137         ln -s "../php-${pkgver}/configure"
 138         ./configure ${_phpconfig} \
 139                 --enable-cgi \
 140                 --enable-fpm \
 141                 --with-fpm-systemd \
 142                 --with-fpm-acl \
 143                 --with-fpm-user=http \
 144                 --with-fpm-group=http \
 145                 --enable-embed=shared \
 146                 ${_phpextensions}
 147         make
 148
 149         # apache
 150         # reuse the previous run; this will save us a lot of time
 151         cp -a "${srcdir}/build" "${srcdir}/build-apache"
 152         cd "${srcdir}/build-apache"
 153         ./configure ${_phpconfig} \
 154                 --with-apxs2 \
 155                 ${_phpextensions}
 156         make
 157
 158         # phpdbg
 159         cp -a "${srcdir}/build" "${srcdir}/build-phpdbg"
 160         cd "${srcdir}/build-phpdbg"
 161         ./configure ${_phpconfig} \
 162                 --enable-phpdbg \
 163                 ${_phpextensions}
 164         make
 165 }
 166
 167 check() {
 168         cd "${srcdir}/build"
 169
 170         # Check if sendmail was configured correctly (FS#47600)
 171         sapi/cli/php -n -r 'echo ini_get("sendmail_path");' | grep -q '/usr/bin/sendmail'
 172
 173         export REPORT_EXIT_STATUS=1
 174         export NO_INTERACTION=1
 175         export SKIP_ONLINE_TESTS=1
 176         export SKIP_SLOW_TESTS=1
 177         export TEST_PHP_ARGS="-j$(nproc)"
 178         export TESTS='tests Zend'
 179
 180         make test
 181 }
 182
 183 package_php-legacy() {
 184         pkgdesc='A general-purpose scripting language that is especially suited to web development'
 185         depends=('libxml2' 'curl' 'libzip' 'pcre2' 'argon2' 'oniguruma' 'gdbm')
 186         provides=("php-interpreter=$_interpreter")
 187         backup=('etc/php-legacy/php.ini')
 188
 189         cd "${srcdir}/build"
 190         make -j1 INSTALL_ROOT="${pkgdir}" install-{modules,cli,build,headers,programs,pharcmd}
 191         install -D -m644 "${srcdir}/php-${pkgver}/php.ini-production" "${pkgdir}/etc/php-legacy/php.ini"
 192         install -d -m755 "${pkgdir}/etc/php-legacy/conf.d/"
 193
 194         # remove static modules
 195         rm -f "${pkgdir}/usr/lib/php-legacy/modules/"*.a
 196         # remove modules provided by sub packages
 197         rm -f "${pkgdir}/usr/lib/php-legacy/modules/"{enchant,gd,intl,sodium,odbc,pdo_dblib,pdo_odbc,pgsql,pdo_pgsql,pspell,snmp,sqlite3,pdo_sqlite,tidy,xsl}.so
 198         # remove empty directory
 199         rmdir "${pkgdir}/usr/include/php-legacy/php/include"
 200 }
 201
 202 package_php-legacy-cgi() {
 203         pkgdesc='CGI and FCGI SAPI for PHP'
 204         depends=('php-legacy')
 205
 206         cd "${srcdir}/build"
 207         make -j1 INSTALL_ROOT="${pkgdir}" install-cgi
 208 }
 209
 210 package_php-legacy-apache() {
 211         pkgdesc='Apache SAPI for PHP'
 212         depends=('php-legacy' 'apache' 'libnsl')
 213         backup=('etc/httpd/conf/extra/php-legacy_module.conf')
 214
 215         install -D -m755 "${srcdir}/build-apache/libs/libphp.so" "${pkgdir}/usr/lib/httpd/modules/libphp-legacy.so"
 216         install -D -m644 "${srcdir}/apache.conf" "${pkgdir}/etc/httpd/conf/extra/php-legacy_module.conf"
 217 }
 218
 219 package_php-legacy-fpm() {
 220         pkgdesc='FastCGI Process Manager for PHP'
 221         depends=('php-legacy' 'systemd')
 222         backup=('etc/php-legacy/php-fpm.conf' 'etc/php-legacy/php-fpm.d/www.conf')
 223         options=('!emptydirs')
 224
 225         cd "${srcdir}/build"
 226         make -j1 INSTALL_ROOT="${pkgdir}" install-fpm
 227         install -D -m644 sapi/fpm/php-fpm.service "${pkgdir}/usr/lib/systemd/system/php-legacy-fpm.service"
 228         install -D -m644 "${srcdir}/php-fpm.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/php-legacy-fpm.conf"
 229 }
 230
 231 package_php-legacy-embed() {
 232         pkgdesc='Embedded PHP SAPI library'
 233         depends=('php-legacy' 'systemd-libs' 'libnsl' 'libxcrypt')
 234         options=('!emptydirs')
 235
 236         cd "${srcdir}/build"
 237         make -j1 INSTALL_ROOT="${pkgdir}" PHP_SAPI=embed install-sapi
 238         mv "${pkgdir}/usr/lib/libphp.so" "${pkgdir}/usr/lib/libphp-legacy.so"
 239 }
 240
 241 package_php-legacy-phpdbg() {
 242         pkgdesc='Interactive PHP debugger'
 243         depends=('php-legacy')
 244         options=('!emptydirs')
 245
 246         cd "${srcdir}/build-phpdbg"
 247         make -j1 INSTALL_ROOT="${pkgdir}" install-phpdbg
 248 }
 249
 250 package_php-legacy-dblib() {
 251         pkgdesc='dblib module for PHP'
 252         depends=('php-legacy' 'freetds')
 253
 254         install -D -m755 "${srcdir}/build/modules/pdo_dblib.so" "${pkgdir}/usr/lib/php-legacy/modules/pdo_dblib.so"
 255 }
 256
 257 package_php-legacy-enchant() {
 258         pkgdesc='enchant module for PHP'
 259         depends=('php-legacy' 'enchant')
 260
 261         install -D -m755 "${srcdir}/build/modules/enchant.so" "${pkgdir}/usr/lib/php-legacy/modules/enchant.so"
 262 }
 263
 264 package_php-legacy-gd() {
 265         pkgdesc='gd module for PHP'
 266         depends=('php-legacy' 'gd')
 267
 268         install -D -m755 "${srcdir}/build/modules/gd.so" "${pkgdir}/usr/lib/php-legacy/modules/gd.so"
 269 }
 270
 271 package_php-legacy-intl() {
 272         pkgdesc='intl module for PHP'
 273         depends=('php-legacy' 'icu')
 274
 275         install -D -m755 "${srcdir}/build/modules/intl.so" "${pkgdir}/usr/lib/php-legacy/modules/intl.so"
 276 }
 277
 278 package_php-legacy-sodium() {
 279         pkgdesc='sodium module for PHP'
 280         depends=('php-legacy' 'libsodium')
 281
 282         install -D -m755 "${srcdir}/build/modules/sodium.so" "${pkgdir}/usr/lib/php-legacy/modules/sodium.so"
 283 }
 284
 285 package_php-legacy-odbc() {
 286         pkgdesc='ODBC modules for PHP'
 287         depends=('php-legacy' 'unixodbc')
 288
 289         install -D -m755 "${srcdir}/build/modules/odbc.so" "${pkgdir}/usr/lib/php-legacy/modules/odbc.so"
 290         install -D -m755 "${srcdir}/build/modules/pdo_odbc.so" "${pkgdir}/usr/lib/php-legacy/modules/pdo_odbc.so"
 291 }
 292
 293 package_php-legacy-pgsql() {
 294         pkgdesc='PostgreSQL modules for PHP'
 295         depends=('php-legacy' 'postgresql-libs')
 296
 297         install -D -m755 "${srcdir}/build/modules/pgsql.so" "${pkgdir}/usr/lib/php-legacy/modules/pgsql.so"
 298         install -D -m755 "${srcdir}/build/modules/pdo_pgsql.so" "${pkgdir}/usr/lib/php-legacy/modules/pdo_pgsql.so"
 299 }
 300
 301 package_php-legacy-pspell() {
 302         pkgdesc='pspell module for PHP'
 303         depends=('php-legacy' 'aspell')
 304
 305         install -D -m755 "${srcdir}/build/modules/pspell.so" "${pkgdir}/usr/lib/php-legacy/modules/pspell.so"
 306 }
 307
 308 package_php-legacy-snmp() {
 309         pkgdesc='snmp module for PHP'
 310         depends=('php-legacy' 'net-snmp')
 311
 312         install -D -m755 "${srcdir}/build/modules/snmp.so" "${pkgdir}/usr/lib/php-legacy/modules/snmp.so"
 313 }
 314
 315 package_php-legacy-sqlite() {
 316         pkgdesc='sqlite module for PHP'
 317         depends=('php-legacy' 'sqlite')
 318
 319         install -D -m755 "${srcdir}/build/modules/sqlite3.so" "${pkgdir}/usr/lib/php-legacy/modules/sqlite3.so"
 320         install -D -m755 "${srcdir}/build/modules/pdo_sqlite.so" "${pkgdir}/usr/lib/php-legacy/modules/pdo_sqlite.so"
 321 }
 322
 323 package_php-legacy-tidy() {
 324         pkgdesc='tidy module for PHP'
 325         depends=('php-legacy' 'tidy')
 326
 327         install -D -m755 "${srcdir}/build/modules/tidy.so" "${pkgdir}/usr/lib/php-legacy/modules/tidy.so"
 328 }
 329
 330 package_php-legacy-xsl() {
 331         pkgdesc='xsl module for PHP'
 332         depends=('php-legacy' 'libxslt')
 333
 334         install -D -m755 "${srcdir}/build/modules/xsl.so" "${pkgdir}/usr/lib/php-legacy/modules/xsl.so"
 335 }