gyp/repos/extra-any/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gyp
   4 pkgver=20220404.9ecf45e3
   5 pkgrel=2
   6 pkgdesc='"Generate Your Projects" Meta-Build system'
   7 url="https://gyp.gsrc.io/"
   8 arch=(any)
   9 license=(custom:BSD)
  10 depends=(python-six ninja)
  11 makedepends=(git python-setuptools)
  12 _commit=9ecf45e37677743503342ee4c6a76eaee80e4a7f  # changes/24/3562924/3
  13 source=("git+https://chromium.googlesource.com/external/gyp#commit=$_commit"
  14         0001-gyp-python38.patch
  15         0002-gyp-fix-cmake.patch
  16         0003-gyp-fips.patch)
  17 sha256sums=('SKIP'
  18             '7fb04acbac92a1d173c2bc3022b7814a711427225a7fd32912dc60f1e1a6746e'
  19             '8a9f1a413b943dd469f981ee5fa7b7cc372e3cd9e9f0ecf9640d4f0f6bb29647'
  20             'dda2c6717d52a9dd53ce5b4985115f947dcca2bce3a207bd9c543976c41decf5')
  21
  22 pkgver() {
  23   cd gyp
  24
  25   # Commit date + short rev
  26   echo $(TZ=UTC git show -s --pretty=%cd --date=format-local:%Y%m%d HEAD).$(git rev-parse --short HEAD)
  27 }
  28
  29 prepare() {
  30   cd gyp
  31
  32   # Python 3 fixes from Fedora
  33   git apply -3 ../*.patch
  34 }
  35
  36 build() {
  37   cd gyp
  38   python setup.py build
  39 }
  40
  41 package() {
  42   cd gyp
  43   python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  44   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENSE
  45 }