gnome-shell-extensions/repos/extra-any/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gnome-shell-extensions
   4 pkgver=44.0
   5 pkgrel=1
   6 pkgdesc="Extensions for GNOME shell, including classic mode"
   7 url="https://wiki.gnome.org/Projects/GnomeShell/Extensions"
   8 arch=(any)
   9 license=(GPL)
  10 depends=(gnome-shell)
  11 makedepends=(
  12   git
  13   meson
  14   sassc
  15 )
  16 optdepends=('gnome-menus: applications menu extension')
  17 groups=(gnome)
  18 _commit=58b4b3c8d6c48432c81c4070829b29db5950a9cb  # tags/44.0^0
  19 source=(
  20   "git+https://gitlab.gnome.org/GNOME/gnome-shell-extensions.git#commit=$_commit"
  21   "git+https://gitlab.gnome.org/GNOME/gnome-shell-sass.git"
  22 )
  23 sha256sums=('SKIP'
  24             'SKIP')
  25
  26 pkgver() {
  27   cd $pkgname
  28   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  29 }
  30
  31 prepare() {
  32   cd $pkgname
  33
  34   git submodule init
  35   git submodule set-url data/gnome-shell-sass "$srcdir/gnome-shell-sass"
  36   git -c protocol.file.allow=always submodule update
  37 }
  38
  39 build() {
  40   local meson_options=(
  41     -D extension_set=all
  42     -D classic_mode=true
  43   )
  44
  45   arch-meson $pkgname build "${meson_options[@]}"
  46   meson compile -C build
  47 }
  48
  49 check() {
  50   meson test -C build --print-errorlogs
  51 }
  52
  53 package() {
  54   meson install -C build --destdir "$pkgdir"
  55 }
  56
  57 # vim:set sw=2 sts=-1 et: