gupnp-igd/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Eric Bélanger <eric@archlinux.org>
   3
   4 pkgname=gupnp-igd
   5 pkgver=1.6.0
   6 pkgrel=1
   7 pkgdesc="A library to handle UPnP IGD port mapping"
   8 url="https://wiki.gnome.org/Projects/GUPnP"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(gupnp)
  12 makedepends=(
  13   git
  14   gobject-introspection
  15   gtk-doc
  16   meson
  17 )
  18 _commit=e60764858374d776869605d39e5e4d1033e9ad4a  # tags/1.6.0^0
  19 source=("git+https://gitlab.gnome.org/GNOME/gupnp-igd.git#commit=$_commit")
  20 b2sums=('SKIP')
  21
  22 pkgver() {
  23   cd $pkgname
  24   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd $pkgname
  29 }
  30
  31 build() {
  32   arch-meson $pkgname build -D gtk_doc=true
  33   meson compile -C build
  34 }
  35
  36 check() {
  37   # No multicast in our containers?
  38   meson test -C build --print-errorlogs || :
  39 }
  40
  41 package() {
  42   depends+=(libg{lib,object,io}-2.0.so libg{ssdp,upnp}-1.6.so)
  43   provides+=(libgupnp-igd-1.6.so)
  44
  45   meson install -C build --destdir "$pkgdir"
  46 }
  47
  48 # vim:set sw=2 sts=-1 et: