libpst/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgbase=libpst
   5 pkgname=(libpst libpst-docs)
   6 pkgver=0.6.76
   7 pkgrel=9
   8 pkgdesc="Outlook .pst file converter"
   9 url="https://www.five-ten-sg.com/libpst/"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(
  13   gcc-libs
  14   libgsf
  15 )
  16 makedepends=(
  17   autoconf-archive
  18   docbook-xsl
  19   doxygen
  20   git
  21   graphviz
  22   xmlto
  23 )
  24 _commit=d963f2adf9fb7e65cdccbf7d35ceb06c63100f80  # tags/libpst-0.6.76
  25 source=("git+https://github.com/pst-format/libpst#commit=$_commit")
  26 sha256sums=('SKIP')
  27
  28 pkgver() {
  29   cd $pkgbase
  30   git describe --tags | sed 's/^libpst-//;s/[^-]*-g/r&/;s/-/+/g'
  31 }
  32
  33 prepare() {
  34   cd $pkgbase
  35
  36   # Build fixes
  37   git cherry-pick -n df169eaeaa3a0aad7244c081497a01ceee15da72 \
  38                      81252ea84b5a6a1e0d3cbcfaf4505729a1057018 \
  39                      db5933678ac44f9153d0c3dd20a6cb91a6887096 \
  40                      52adecb804f4d8fa1697692e177e972eb891fcb2
  41
  42   # Fix _FORTIFY_SOURCE warnings
  43   git cherry-pick -n b34d3d8eb679e3598dd9970bb35e6ab60fdd9805
  44
  45   autoreconf -fvi
  46 }
  47
  48 build() {
  49   local configure_options=(
  50     --prefix=/usr
  51     --sysconfdir=/etc
  52     --localstatedir=/var
  53     --mandir=/usr/share/man
  54     --disable-dii
  55     --disable-python
  56     --disable-static
  57     --enable-libpst-shared
  58   )
  59
  60   cd $pkgbase
  61   ./configure "${configure_options[@]}"
  62   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  63   make -C xml all
  64   make
  65 }
  66
  67 package_libpst() {
  68   provides=(libpst.so)
  69
  70   make -C $pkgbase DESTDIR="$pkgdir" install
  71
  72   mkdir -p doc/usr/share
  73   mv {"$pkgdir",doc}/usr/share/doc
  74 }
  75
  76 package_libpst-docs() {
  77   pkgdesc+=" (documentation)"
  78   depends=()
  79
  80   mv doc/* "$pkgdir"
  81 }
  82
  83 # vim:set sw=2 sts=-1 et: