lzo/repos/core-x86_64/PKGBUILD

   1 # Contributor: Low Kian Seong <fastmail_low@speedymail.org>
   2 # Maintainer: dorphell <dorphell@archlinux.org>
   3
   4 pkgname=lzo
   5 pkgver=2.10
   6 pkgrel=5
   7 pkgdesc="Portable lossless data compression library"
   8 arch=('x86_64')
   9 url="https://www.oberhumer.com/opensource/lzo"
  10 license=('GPL')
  11 depends=('glibc')
  12 provides=('liblzo2.so' 'libminilzo.so')
  13 options=('debug')
  14 source=(https://www.oberhumer.com/opensource/lzo/download/lzo-${pkgver}.tar.gz)
  15 sha256sums=('c0f892943208266f9b6543b3ae308fab6284c5c90e627931446fb49b4221a072')
  16
  17 build() {
  18   cd lzo-${pkgver}
  19   ./configure --prefix=/usr --enable-shared
  20   make
  21
  22   # build minilzo
  23   gcc $CPPFLAGS $CFLAGS -fpic -Iinclude/lzo -o minilzo/minilzo.o -c minilzo/minilzo.c
  24   gcc $LDFLAGS -shared -o libminilzo.so.0 -Wl,-soname,libminilzo.so.0 minilzo/minilzo.o
  25 }
  26
  27 check() {
  28   cd lzo-${pkgver}
  29   make test # Larger test
  30   make check
  31 }
  32
  33 package() {
  34   cd lzo-${pkgver}
  35   make DESTDIR="${pkgdir}" install
  36
  37   # install minilzo
  38   install -m 755 libminilzo.so.0 "${pkgdir}"/usr/lib
  39   install -p -m 644 minilzo/minilzo.h ${pkgdir}/usr/include/lzo
  40   cd "${pkgdir}"/usr/lib
  41   ln -s libminilzo.so.0 libminilzo.so
  42 }