perl-text-roman/trunk/PKGBUILD

   1 # $ID$
   2 # Maintainer: Rémy Oudompheng <remy@archlinux.org>
   3
   4 pkgname=perl-text-roman
   5 _dist=Text-Roman
   6 pkgver=3.5
   7 pkgrel=9
   8 pkgdesc="Allows conversion between Roman and Arabic algarisms"
   9 arch=('any')
  10 url="https://metacpan.org/release/${_dist}"
  11 license=('PerlArtistic' 'GPL')
  12 depends=('perl')
  13 options=('!emptydirs')
  14 source=(https://search.cpan.org/CPAN/authors/id/S/SY/SYP/${_dist}-${pkgver}.tar.gz)
  15 md5sums=('1f6b09c0cc1f4425b565ff787a39fd83')
  16 sha512sums=('597ca054094f58c0983c66ce2b22dbc4d69861b02495663987e6b66dc0044a0d7e18e51ef817ed3c76832d283c01c6f9f51e68af7cb6b186b27553b5a877bc33')
  17
  18 build() {
  19     cd "${srcdir}/${_dist}-${pkgver}"
  20     unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  21     export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  22     perl Makefile.PL
  23     make
  24 }
  25
  26 check() {
  27     cd "${srcdir}/${_dist}-${pkgver}"
  28     unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  29     export PERL_MM_USE_DEFAULT=1
  30     make test
  31 }
  32
  33 package() {
  34     cd "${srcdir}/${_dist}-${pkgver}"
  35     unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  36     make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
  37 }