perl-locale-gettext/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Giovanni Scafora <giovanni@archlinux.org>
   2 # Contributor: Mark Rosenstand <mark@borkware.net>
   3 # Contributor: Paul Mattal <paul@archlinux.org>
   4
   5 pkgname=perl-locale-gettext
   6 _realname=Locale-gettext
   7 pkgver=1.07
   8 pkgrel=13
   9 pkgdesc="Permits access from Perl to the gettext() family of functions"
  10 arch=('x86_64')
  11 license=('GPL' 'PerlArtistic')
  12 url="https://search.cpan.org/dist/${_realname}/"
  13 depends=('gettext' 'perl')
  14 options=(!emptydirs)
  15 source=("https://search.cpan.org/CPAN/authors/id/P/PV/PVANDRY/${_realname}-${pkgver}.tar.gz")
  16 sha256sums=('909d47954697e7c04218f972915b787bd1244d75e3bd01620bc167d5bbc49c15')
  17
  18 build() {
  19   cd "${srcdir}/${_realname}-${pkgver}"
  20
  21   # install module in vendor directories.
  22   PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  23   make
  24 }
  25
  26 check() {
  27   cd "${srcdir}/${_realname}-${pkgver}"
  28
  29   make test
  30 }
  31
  32 package() {
  33   cd "${srcdir}/${_realname}-${pkgver}"
  34   make install DESTDIR="${pkgdir}"
  35
  36   # remove perllocal.pod and .packlist
  37   find "${pkgdir}" -name perllocal.pod -delete
  38   find "${pkgdir}" -name .packlist -delete
  39 }