xkeyboard-config/trunk/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2
   3 pkgname=xkeyboard-config
   4 pkgver=2.38
   5 pkgrel=1
   6 pkgdesc="X keyboard configuration files"
   7 arch=(any)
   8 license=('custom')
   9 url="https://gitlab.freedesktop.org/xkeyboard-config/xkeyboard-config"
  10 makedepends=('xorg-xkbcomp' 'libxslt' 'python' 'meson' 'git')
  11 provides=('xkbdata')
  12 replaces=('xkbdata')
  13 conflicts=('xkbdata')
  14 # https://gitlab.freedesktop.org/xkeyboard-config/xkeyboard-config
  15 source=(https://xorg.freedesktop.org/archive/individual/data/${pkgname}/${pkgname}-${pkgver}.tar.xz{,.sig})
  16 validpgpkeys=('FFB4CCD275AAA422F5F9808E0661D98FC933A145') # Sergey Udaltsov <sergey.udaltsov@gmail.com>
  17 sha256sums=('0690a91bab86b18868f3eee6d41e9ec4ce6894f655443d490a2184bfac56c872'
  18             'SKIP')
  19
  20 build() {
  21   arch-meson ${pkgname}-${pkgver} build \
  22         -D xkb-base="/usr/share/X11/xkb" \
  23         -D compat-rules=true \
  24         -D xorg-rules-symlinks=true
  25
  26   # Print config
  27   meson configure build
  28
  29   ninja -C build
  30
  31  }
  32
  33  package() {
  34
  35   DESTDIR="$pkgdir" ninja -C build install
  36
  37   install -m755 -d "${pkgdir}/var/lib/xkb"
  38   install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  39   install -m644 ${pkgname}-${pkgver}/COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
  40 }