elementary/trunk/PKGBUILD

   1 # Maintainer: Ronald van Haren <ronald@archlinux.org>
   2 # Contributor: Gustavo Sverzut Barbieri <barbieri@gmail.com>
   3
   4 pkgbase=elementary
   5 pkgname=('elementary' 'elementary-docs')
   6 pkgver=1.17.1
   7 pkgrel=1
   8 pkgdesc="Enlightenment's widget set"
   9 arch=('x86_64')
  10 url="http://www.enlightenment.org"
  11 license=('BSD')
  12 depends=('efl' 'evas_generic_loaders')
  13 makedepends=('doxygen' 'imagemagick' 'texlive-core' 'ghostscript')
  14 options=('!emptydirs')
  15 source=(http://download.enlightenment.org/rel/libs/${pkgname}/${pkgname}-${pkgver}.tar.gz)
  16 sha1sums=('87df0183b91c623716a4d283f4147dd8815f5a24')
  17
  18 build() {
  19   cd "${srcdir}/${pkgname}-${pkgver}"
  20
  21   export CFLAGS="$CFLAGS -fvisibility=hidden"
  22
  23   ./configure \
  24     --prefix=/usr \
  25     --disable-static
  26   make
  27   #make -j1 doc # building docs hangs the compilation
  28   cd doc
  29   doxygen
  30 }
  31
  32 package_elementary(){
  33   cd "${srcdir}/${pkgname}-${pkgver}"
  34   make DESTDIR=${pkgdir} install
  35
  36   # install license files
  37   install -Dm644 "${srcdir}/${pkgname}-${pkgver}/COPYING" \
  38         "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
  39 }
  40
  41 package_elementary-docs() {
  42   pkgdesc="Documentation for Elementary GUI toolkit"
  43   depends=()
  44
  45   cd "${srcdir}/${pkgbase}-${pkgver}"
  46   install -d "${pkgdir}/usr/share/doc/${pkgbase}"
  47   cp -a doc/html "${pkgdir}/usr/share/doc/${pkgbase}/html"
  48   cp -a doc/latex "${pkgdir}/usr/share/doc/${pkgbase}/latex"
  49 }
  50
  51