libva-intel-driver/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   4
   5 pkgname=libva-intel-driver
   6 pkgver=2.4.1
   7 pkgrel=2
   8 pkgdesc='VA-API implementation for Intel G45 and HD Graphics family'
   9 arch=(x86_64)
  10 url=https://01.org/linuxmedia/vaapi
  11 license=(MIT)
  12 depends=(
  13   libva
  14   libdrm
  15 )
  16 makedepends=(
  17   git
  18   meson
  19 )
  20 replaces=(libva-driver-intel)
  21 source=(git+https://github.com/intel/intel-vaapi-driver.git#tag=9a1f0c64174f970a26380d4957583c71372fbb7c)
  22 sha256sums=('SKIP')
  23
  24 pkgver() {
  25   cd intel-vaapi-driver
  26
  27   git describe --tags
  28 }
  29
  30 prepare() {
  31   cd intel-vaapi-driver
  32
  33   # Only relevant if intel-gpu-tools is installed,
  34   # since then the shaders will be recompiled
  35   sed -i '1s/python$/&2/' src/shaders/gpp.py
  36 }
  37
  38 build() {
  39   CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  40   arch-meson intel-vaapi-driver build
  41   ninja -C build
  42 }
  43
  44 package() {
  45   DESTDIR="${pkgdir}" meson install -C build
  46   install -Dm 644 intel-vaapi-driver/COPYING -t "${pkgdir}"/usr/share/licenses/libva-intel-driver
  47 }
  48
  49 # vim: ts=2 sw=2 et: