appstream-glib/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Maintainer: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=appstream-glib
   5 pkgver=0.7.18
   6 pkgrel=2
   7 pkgdesc="Objects and methods for reading and writing AppStream metadata"
   8 url="https://people.freedesktop.org/~hughsient/appstream-glib/"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(gtk3 libyaml pacman gcab libsoup libstemmer)
  12 makedepends=(gobject-introspection gtk-doc git gperf meson)
  13 provides=(appdata-tools libappstream-glib.so)
  14 conflicts=(appdata-tools)
  15 replaces=(appdata-tools)
  16 _commit=705e8e2061e9c9ef741792b1de56c6529fb57082  # tags/appstream_glib_0_7_18^0
  17 source=("git+https://github.com/hughsie/appstream-glib#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/^appstream_glib_//;s/_/./g;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27 }
  28
  29 build() {
  30   arch-meson $pkgname build \
  31     -D alpm=true \
  32     -D gtk-doc=true \
  33     -D rpm=false
  34   meson compile -C build
  35 }
  36
  37 check() {
  38   meson test -C build --print-errorlogs
  39 }
  40
  41 package() {
  42   DESTDIR="$pkgdir" meson install -C build
  43 }