conky/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   3 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   4 # Contributor: James Rayner <james@archlinux.org>
   5 # Contributor: Partha Chowdhury <kira.laucas@gmail.com>
   6
   7 pkgname=conky
   8 pkgver=1.12.2
   9 _gitcommit=52e5aa53b4c76973519a770949dc8bdca0145325
  10 pkgrel=2
  11 pkgdesc='Lightweight system monitor for X'
  12 url='https://github.com/brndnmtthws/conky'
  13 license=('BSD' 'GPL')
  14 arch=('x86_64')
  15 makedepends=('cmake' 'docbook2x' 'docbook-xsl' 'man-db' 'git' 'catch2')
  16 depends=(
  17   'glibc' 'glib2' 'lua' 'wireless_tools' 'libxdamage' 'libxinerama' 'libxft' 'imlib2'
  18   'libxml2' 'libpulse' 'libxnvctrl' 'systemd-libs' 'ncurses' 'curl'
  19   libncursesw.so libXNVCtrl.so libsystemd.so libpulse.so libcurl.so)
  20 source=("git+https://github.com/brndnmtthws/conky.git#tag=${_gitcommit}?signed")
  21 sha512sums=('SKIP')
  22 b2sums=('SKIP')
  23 validpgpkeys=(
  24   'EB2E847572A71BE20F59AFBEB49ABB7270D9D4FD' # Brenden Matthews
  25 )
  26
  27 pkgver() {
  28   cd ${pkgname}
  29   git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
  30 }
  31
  32 prepare() {
  33   cd $pkgname
  34 # Unbundle catch2 to fix build with glibc 2.35
  35   rm -r tests/catch2
  36   ln -s /usr/include/catch2 tests
  37 }
  38
  39 build() {
  40   cd ${pkgname}
  41   cmake \
  42     -B build \
  43     -D CMAKE_BUILD_TYPE=Release \
  44     -D CMAKE_CXX_FLAGS="$CXXFLAGS -ffat-lto-objects" \
  45     -D MAINTAINER_MODE=ON \
  46     -D BUILD_DOCS=ON \
  47     -D BUILD_WLAN=ON \
  48     -D BUILD_XDBE=ON \
  49     -D BUILD_XSHAPE=ON \
  50     -D BUILD_IMLIB2=ON \
  51     -D BUILD_CURL=ON \
  52     -D BUILD_RSS=ON \
  53     -D BUILD_NVIDIA=ON \
  54     -D BUILD_WEATHER_METAR=ON \
  55     -D BUILD_PULSEAUDIO=ON \
  56     -D BUILD_JOURNAL=ON \
  57     -D CMAKE_INSTALL_PREFIX=/usr \
  58     -Wno-dev \
  59     -S .
  60
  61   make -C build
  62 }
  63
  64 package() {
  65   cd ${pkgname}
  66   make -C build DESTDIR="${pkgdir}" install
  67   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  68   install -Dm 644 extras/vim/syntax/conkyrc.vim -t "${pkgdir}"/usr/share/vim/vimfiles/syntax
  69   install -Dm 644 extras/vim/ftdetect/conkyrc.vim -t "${pkgdir}"/usr/share/vim/vimfiles/ftdetect
  70 }
  71
  72 # vim: ts=2 sw=2 et: