kbd/trunk/PKGBUILD

   1 # Maintainer: Tobias Powalowski <tpowa@archlinux.org>
   2
   3 pkgname=kbd
   4 pkgver=2.5.1
   5 pkgrel=1
   6 pkgdesc="Keytable files and keyboard utilities"
   7 arch=('x86_64')
   8 url="http://www.kbd-project.org"
   9 license=('GPL')
  10 depends=('glibc' 'pam')
  11 makedepends=('check' 'git')
  12 #source=(https://www.kernel.org/pub/linux/utils/${pkgname}/${pkgname}-${pkgver}.tar.gz
  13 #        https://www.kernel.org/pub/linux/utils/kbd/${pkgname}-${pkgver}.tar.sign
  14 source=(git+https://git.kernel.org/pub/scm/linux/kernel/git/legion/kbd.git#tag=v$pkgver?signed
  15         'fix-euro2.patch'
  16         'vlock.pam')
  17 backup=('etc/pam.d/vlock')
  18 provides=('vlock')
  19 conflicts=('vlock')
  20 replaces=('vlock')
  21 sha256sums=('SKIP'
  22             'a5e0167b6a82a9eb4d581d56baab930c2d80f5541dc34630460b73e1115384b8'
  23             '5c2d377a87121e7c399534fb91e2ffc0cc1e75d44a8f07ee6f55c9c089bc81e4')
  24 validpgpkeys=(
  25               '7F2A3D07298149A0793C9A4EA45ABA544CFFD434' #Alexey Gladkov
  26              )
  27
  28 prepare() {
  29   cd ${pkgname}
  30   # rename keymap files with the same names
  31   # this is needed because when only name of keymap is specified
  32   # loadkeys loads the first keymap it can find, which is bad (see FS#13837)
  33   # this should be removed when upstream adopts the change
  34   mv data/keymaps/i386/qwertz/cz{,-qwertz}.map
  35   mv data/keymaps/i386/olpc/es{,-olpc}.map
  36   mv data/keymaps/i386/olpc/pt{,-olpc}.map
  37   mv data/keymaps/i386/fgGIod/trf{,-fgGIod}.map
  38   mv data/keymaps/i386/colemak/{en-latin9,colemak}.map
  39   # fix euro2 #28213
  40   patch -Np1 -i ../fix-euro2.patch
  41   autoreconf -if
  42 }
  43
  44 build() {
  45   cd ${pkgname}
  46   ./configure --prefix=/usr --sysconfdir=/etc --datadir=/usr/share/kbd --mandir=/usr/share/man
  47   make KEYCODES_PROGS=yes RESIZECONS_PROGS=yes
  48 }
  49
  50 check() {
  51   cd ${pkgname}
  52
  53 # This test is expected to fail since kbd-fix-loadkmap-compat.patch modifies the binary format
  54   sed -e 's|dumpkeys-bkeymap ||' -i tests/Makefile
  55
  56   make check
  57 }
  58
  59 package() {
  60   cd ${pkgname}
  61   make KEYCODES_PROGS=yes RESIZECONS_PROGS=yes DESTDIR="${pkgdir}" install
  62   install -Dm644 ../vlock.pam "${pkgdir}"/etc/pam.d/vlock
  63 }