libqmi/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=libqmi
   4 pkgver=1.30.6
   5 pkgrel=1
   6 pkgdesc="QMI modem protocol helper library"
   7 url="https://www.freedesktop.org/wiki/Software/libqmi/"
   8 arch=(x86_64)
   9 license=(GPL2)
  10 depends=(libmbim libqrtr-glib libgudev)
  11 makedepends=(gtk-doc meson git help2man gobject-introspection bash-completion)
  12 provides=(libqmi-glib.so)
  13 options=(debug)
  14 _commit=dc82a0ae42df0086fab0595690dd3bbd7a958773  # tags/1.30.6^0
  15 source=("git+https://gitlab.freedesktop.org/mobile-broadband/libqmi.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd libqmi
  20   git describe --tags | sed 's/-rc/rc/;s/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd libqmi
  25 }
  26
  27 build() {
  28   arch-meson libqmi build -D gtk_doc=false  # Docs currently broken
  29   meson compile -C build
  30 }
  31
  32 check() {
  33   meson test -C build --print-errorlogs
  34 }
  35
  36 package() {
  37   meson install -C build --destdir "$pkgdir"
  38 }